Domande dai principianti MQL5 MT5 MetaTrader 5 - pagina 1192

Nuovo commento
 
Artem Mordvinkin:


È scritto in parole povere che i simboli sono automaticamente collegati al test

Quando vi si accede.
 
Artem Mordvinkin:


Sì, è scritto in russo che i simboli sono collegati automaticamente durante il test

Per creare un indicatore, devi prima collegare un simbolo in Market Watch (nel tuo caso in Market Watch del tester).

 
Artyom Trishkin:
Richiedete qualsiasi dato da ogni simbolo desiderato.

Mancano da SymbolSelect() - non selezionati

Cari signori prima di riferirmi alle pubblicazioni (per le quali vi ringrazio) controllate - se le vostre multicurrencies funzionano nel tester E se lo fanno, ha senso

 
Artem Mordvinkin:

Mancano da SymbolSelect() - non selezionati

Cari signori prima di riferirmi alle pubblicazioni (per le quali vi ringrazio) controllate - se le vostre multicurrencies funzionano nel tester E se lo fanno, ha senso

Funzionano. Sull'ultima build. Nessun problema.
 
Artyom Trishkin:
Funziona. Sull'ultima build. Nessun problema.

Come li hai collegati (simboli) - puoi dirmi quale funzione?

 
Artem Mordvinkin:

Come li hai collegati (simboli) - puoi dirmi quale funzione?

SymbolSelect(nome del carattere, vero);

 
Vladimir Karputov:

SymbolSelect(nome del carattere, vero);

Io faccio lo stesso.

SymbolSelect(EURUSD_inst, true);
  SymbolSelect(GBPUSD_inst, true);
  SymbolSelect(USDJPY_inst, true);
  SymbolSelect(AUDUSD_inst, true);


Ho capito così

2020.03.09 19:19:45.766 simbolo EURUSDrfd non esiste

2020.03.09 19:19:45.766 simbolo USDJPYrfd non esiste

2020.03.09 19:19:45.766 simbolo AUDUSDrfd non esiste


Il cavo non dà un errore perché è selezionato nel tester.

I nomi dei simboli sono corretti.


UPD mi sembra che debba fare qualcosa nelle impostazioni del terminale stesso. Se tutto funzionava prima dell'ultima build, non ha niente a che fare con il codice. Il tester non può vedere i simboli.

 
Artem Mordvinkin:


2020.03.09 19:19:45.766 simbolo EURUSDrfd non esiste

2020.03.09 19:19:45.766 simbolo USDJPYrfd non esiste

2020.03.09 19:19:45.766 simbolo AUDUSDrfd non esiste


Il cavo non dà un errore perché è selezionato nel tester

Che cos'è? Dov'è il codice? Come si ottiene? Soprattutto state selezionando personaggi completamente diversi.

 
Vladimir Karputov:

Che cos'è? Dov'è il codice? Come si ottiene? Soprattutto perché state scegliendo personaggi completamente diversi.

Capito, facciamo così.

Dato (nome dei personaggi)


Codice (frammenti)

//----------------------------название инструмента
string EURUSD_inst = "EURUSDrfd";
string GBPUSD_inst = "GBPUSDrfd";
string AUDUSD_inst = "AUDUSDrfd";
string USDJPY_inst = "USDJPYrfd";


void OnTick()
  {
  SymbolSelect(EURUSD_inst, true);
  SymbolSelect(GBPUSD_inst, true);
  SymbolSelect(USDJPY_inst, true);
  SymbolSelect(AUDUSD_inst, true);
}

Selezioniamo il cavo nel tester come esempio.


Eseguirlo e

2020.03.09 19:19:45.766 simbolo EURUSDrfd non esiste

2020.03.09 19:19:45.766 simbolo USDJPYrfd non esiste

2020.03.09 19:19:45.766 simbolo AUDUSDrfd non esiste

Non c'è nessun errore sul cavo - è selezionato di default nel tester

E per sicurezza, dirò che questo problema è solo nel tester. E che il gufo ha diversi anni e l'errore è di 2 giorni e che questo è il caso di tutti i miei gufi multi-valuta.
 

Esempio di creazione di un indicatore iMA sul simbolo 'USDJPY', con il tester in esecuzione su 'EURUSD'.

//+------------------------------------------------------------------+
//|                                        iMA Values on a Chart.mq5 |
//|                              Copyright © 2019, Vladimir Karputov |
//+------------------------------------------------------------------+
#property copyright "Copyright © 2019, Vladimir Karputov"
#property version   "1.001"
//--- input parameters
input  string              Inp_MA_symbol        = "USDJPY";    // MA: symbol name
input ENUM_TIMEFRAMES      Inp_MA_period        = PERIOD_D1;   // MA: timeframe
input int                  Inp_MA_ma_period     = 12;          // MA: averaging period
input int                  Inp_MA_ma_shift      = 5;           // MA: horizontal shift
input ENUM_MA_METHOD       Inp_MA_ma_method     = MODE_SMA;    // MA: smoothing type
input ENUM_APPLIED_PRICE   Inp_MA_applied_price = PRICE_CLOSE; // MA: type of price
//---
int    handle_iMA;                           // variable for storing the handle of the iMA indicator
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit()
  {
   if(!SymbolSelect(Inp_MA_symbol,true))
     {
      PrintFormat("Failed select symbol %s",
                  Inp_MA_symbol);
      return(INIT_FAILED);
     }
//--- create handle of the indicator iMA
   handle_iMA=iMA(Inp_MA_symbol,Inp_MA_period,Inp_MA_ma_period,Inp_MA_ma_shift,
                  Inp_MA_ma_method,Inp_MA_applied_price);
//--- if the handle is not created
   if(handle_iMA==INVALID_HANDLE)
     {
      //--- tell about the failure and output the error code
      PrintFormat("Failed to create handle of the iMA indicator for the symbol %s/%s, error code %d",
                  Inp_MA_symbol,
                  EnumToString(Inp_MA_period),
                  GetLastError());
      //--- the indicator is stopped early
      return(INIT_FAILED);
     }
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick()
  {
//---
   double array_ma[];
   ArraySetAsSeries(array_ma,true);
   int start_pos=0,count=3;
   if(!iGetArray(handle_iMA,0,start_pos,count,array_ma))
      return;

   string text="";
   for(int i=0; i<count; i++)
      text=text+IntegerToString(i)+": "+DoubleToString(array_ma[i],Digits()+1)+"\n";
//---
   Comment(text);
  }
//+------------------------------------------------------------------+
//| Get value of buffers                                             |
//+------------------------------------------------------------------+
bool iGetArray(const int handle,const int buffer,const int start_pos,
               const int count,double &arr_buffer[])
  {
   bool result=true;
   if(!ArrayIsDynamic(arr_buffer))
     {
      //if(InpPrintLog)
      PrintFormat("ERROR! EA: %s, FUNCTION: %s, this a no dynamic array!",__FILE__,__FUNCTION__);
      return(false);
     }
   ArrayFree(arr_buffer);
//--- reset error code
   ResetLastError();
//--- fill a part of the iBands array with values from the indicator buffer
   int copied=CopyBuffer(handle,buffer,start_pos,count,arr_buffer);
   if(copied!=count)
     {
      //--- if the copying fails, tell the error code
      //if(InpPrintLog)
      PrintFormat("ERROR! EA: %s, FUNCTION: %s, amount to copy: %d, copied: %d, error code %d",
                  __FILE__,__FUNCTION__,count,copied,GetLastError());
      //--- quit with zero result - it means that the indicator is considered as not calculated
      return(false);
     }
   return(result);
  }
//+------------------------------------------------------------------+

Il risultato è corretto. Prima si seleziona il simbolo e poi si crea l'indicatore con esso.


1...118511861187118811891190119111921193119411951196119711981199...1504
Nuovo commento