DocumentazioneSezioni
MQL5 RiferimentoFunzioni di ConversioneEnumToString 

EnumToString

Conversione di un valore di enumerazione di qualsiasi tipo, in formato testo.

string  EnumToString(
   any_enum  value      // qualsiasi tipo di valore enumerazione
   );

Parametri

valore

[In] Qualsiasi tipo di valore di enumerazione.

Valore restituito

Una stringa con una rappresentazione testuale dell'enumerazione. Per ottenere il messaggio di errore chiamare la funzione GetLastError().

Nota

La funzione può impostare i seguenti valori di errore nella variabile _LastError:

  • ERR_INTERNAL_ERROR – errore dell'ambiente di esecuzione
  • ERR_NOT_ENOUGH_MEMORY – memoria non sufficiente per completare l'operazione
  • ERR_INVALID_PARAMETER – non posso permettere il nome del valore dell'enumerazione

 

Esempio:

enum interval  // enumerazione di costanti nominate
  {
   month=1,     // intervallo un-mese
   two_months,  // due mesi
   quarter,     // tre mesi - un quarto
   halfyear=6,  // metà anno
   year=12,     // un anno - 12 mesi
  };
//+--------------------------------------------------------------------------------+
//| Funzione di avvio del programma Script                                         |
//+--------------------------------------------------------------------------------+
voidOnStart()
  {
//--- Imposta l'intervallo di tempo pari ad un mese
   interval period=month;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- imposta l'intervallo di tempo equivalente ad un quarto (tre mesi)
   period=quarter;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- imposta l'intervallo di tempo uguale ad un anno (12 mesi))
   period=year;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- controlla come viele mostrato il tipo di ordine
   ENUM_ORDER_TYPE type=ORDER_TYPE_BUY;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
//--- controlla come i valori scorretti vengono visualizzati
   type=WRONG_VALUE;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
// Risultato:
// mese=1
// quarto=3
// anno=12
// ORDER_TYPE_BUY=0
// ENUM_ORDER_TYPE::-1=-1
  }

Vedi anche

Enumerazioni, Variabili di input