CryptEncode

int  CryptEncode(
   ENUM_CRYPT_METHOD   method,        // metodo
   const uchar&        data[],        // array sorgente
   const uchar&        key[],         // chiave
   uchar&              result[]       // array di destinazione
   );

//+------------------------------------------------------------------+
//| ArrayToHex                                                       |
//+------------------------------------------------------------------+
string ArrayToHex(uchar &arr[],int count=-1)
  {
   string res="";
//--- controllo
   if(count<0 || count>ArraySize(arr))
      count=ArraySize(arr);
//--- trasformare in stringa HEX
   for(int i=0; i<count; i++)
      res+=StringFormat("%.2X",arr[i]);
//---
   return(res);
  }
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
   string text="The quick brown fox jumps over the lazy dog";
   string keystr="ABCDEFG";
   uchar src[],dst[],key[];
//--- preparare la chiave
   StringToCharArray(keystr,key);
//--- copiare il testo nell'array sorgente src[]
   StringToCharArray(text,src);
//-- stampa i dati iniziali
   PrintFormat("Initial data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
//--- cifra src[] con la chiave DES 56-bit in key[]
   int res=CryptEncode(CRYPT_DES,src,key,dst);
//-- controllare errori
   if(res>0)
     {
 //--- stampa dati cifrati
      PrintFormat("Encoded data: size=%d %s",res,ArrayToHex(dst));
 //-- decodifica dst[] in src[]
      res=CryptDecode(CRYPT_DES,dst,key,src);
      //--- controlare errori 
      if(res>0)
        {
 //-- stampa dati decodificati
         PrintFormat("Decoded data: size=%d, string='%s'",ArraySize(src),CharArrayToString(src));
        }
      else
         Print("Error in CryptDecode. Error code=",GetLastError());
     }
   else
      Print("Error in CryptEncode. Error code=",GetLastError());
  }