ДокументацияРазделы
Справочник MQL5Получение рыночной информацииSymbolInfoTick 

SymbolInfoTick

Возвращает текущие цены  для указанного символа в переменной типа MqlTick.

bool  SymbolInfoTick(
   string    symbol,     // символ
   MqlTick&  tick        // ссылка на структуру
   );

Параметры

symbol

[in]  Имя символа.

tick

[out]  Ссылка на структуру типа MqlTick, в которую будут помещены текущие цены и время последнего обновления цен.

Возвращаемое значение

Возвращает true в случае успеха, иначе false.

Пример:

#define SYMBOL_NAME "EURUSD"
 
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- объявим массив с типом структуры MqlTick размерностью 1
   MqlTick tick[1]={};
   
//--- получим последние цены по символу SYMBOL_NAME в структуру MqlTick
   if(!SymbolInfoTick(SYMBOL_NAME, tick[0]))
     {
      Print("SymbolInfoTick() failed. Error ", GetLastError());
      return;
     }
 
//--- выведем полученные данные в журнал
   PrintFormat("Latest price data for the '%s' symbol:", SYMBOL_NAME);
   ArrayPrint(tick);
   /*
   результат:
   Latest price data for the 'EURUSD' symbol:
                    [time]   [bid]   [ask] [last] [volume]    [time_msc] [flags] [volume_real]
   [0] 2024.05.17 23:58:54 1.08685 1.08695 0.0000        0 1715990334319       6       0.00000
   */
  }