TimeGMT

Возвращает время GMT, которое вычисляется с учётом перехода на зимнее или летнее время по локальному времени компьютера, на котором запущен клиентский терминал. Существует 2 варианта функции.

Вызов без параметров

datetime TimeGMT();

Вызов с параметром типа MqlDateTime

datetime  TimeGMT(
   MqlDateTime&  dt_struct      // переменная типа структуры
   );

Параметры

dt_struct

[out] Переменная типа структуры MqlDateTime.

Возвращаемое значение

Значение типа datetime

Примечание

Если в качестве параметра была передана переменная типа структуры MqlDateTime, то она заполняется соответствующим образом.

Для организации счетчиков и таймеров высокого разрешения нужно использовать функцию GetTickCount(), которая выдает значения в миллисекундах.

При работе в тестере стратегий время TimeGMT() всегда равно моделируемому серверному времени TimeTradeServer().

Пример:

void OnStart()
  {
//--- объявим переменную MqlDateTime для заполнения данными о дате/времени и получим локальное время компьютера и время GMT
   MqlDateTime tm={};
   datetime    time1=TimeLocal();            // первая форма вызова: локальное время компьютера
   datetime    time2=TimeGMT(tm);            // вторая форма вызова: время GMT, вычисленное по локальному времени компьютера с заполнением структуры MqlDateTime
   int         shift=int(time1-time2)/3600;  // смещение локального времени относительно времени GMT

//--- выведем в журнал локальное время и время GMT с данными заполненной структуры MqlDateTime
   PrintFormat("Time Local: %s\nTime GMT: %s\n- Year: %u\n- Month: %02u\n- Day: %02u\n"+
               "- Hour: %02u\n- Min: %02u\n- Sec: %02u\n- Day of Year: %03u\n- Day of Week: %u (%s)\nLocal time offset relative to GMT: %+d",
               (string)time1, (string)time2, tm.year, tm.mon, tm.day, tm.hour, tm.min, tm.sec, tm.day_of_year, tm.day_of_week,
               EnumToString((ENUM_DAY_OF_WEEK)tm.day_of_week), shift);
   /*
   результат:
   Time Local: 2024.04.18 19:37:23
   Time GMT: 2024.04.18 12:37:23
   - Year: 2024
   - Month: 04
   - Day: 18
   - Hour: 12
   - Min: 37
   - Sec: 23
   - Day of Year: 108
   - Day of Week: 4 (THURSDAY)
   Local time offset relative to GMT: +7
   */
  }

TimeLocal

TimeDaylightSavings