//--- 説明
#property description "Script creates a bitmap in the chart window."
//--- スクリプトの起動時に入力パラメータのウィンドウを表示する
#property script_show_inputs
//--- スクリプト入力パラメータ
input string InpFile="\\Images\\dollar.bmp"; // ビットマップファイル名
input int InpWidth=24; // 表示範囲の X 座標
input int InpHeight=24; // 表示範囲の Y 座標
input int InpXOffset=4; // 表示範囲を X 軸に沿ってシフト
input int InpYOffset=4; // 表示範囲を Y 軸に沿ってシフト
input color InpColor=clrRed; // 強調表示時の境界線の色
input ENUM_LINE_STYLE InpStyle=STYLE_SOLID; // 強調表示時の線のスタイル
input int InpPointWidth=1; // 移動のポイントサイズ
input bool InpBack=false; // 背景オブジェクト
input bool InpSelection=false; // 強調表示して移動
input bool InpHidden=true; // オブジェクトリストに隠す
input long InpZOrder=0; // マウスクリックの優先順位
//+------------------------------------------------------------------+
//| チャートウィンドウでビットマップを作成する |
//+------------------------------------------------------------------+
bool BitmapCreate(const long chart_ID=0, // チャート識別子
const string name="Bitmap", // ビットマップ名
const int sub_window=0, // サブウィンドウ番号
datetime time=0, // アンカーポイントの時刻
double price=0, // アンカーポイントの価格
const string file="", // ビットマップファイル名
const int width=10, // 表示範囲の X 座標
const int height=10, // 表示範囲の Y 座標
const int x_offset=0, // 表示範囲を X 軸に沿ってシフト
const int y_offset=0, // 表示範囲を Y 軸に沿ってシフト
const color clr=clrRed, // 強調表示時の境界線の色
const ENUM_LINE_STYLE style=STYLE_SOLID, // 強調表示時の線のスタイル
const int point_width=1, // 移動ポイントサイズ
const bool back=false, // 背景で表示する
const bool selection=false, // 強調表示して移動
const bool hidden=true, // オブジェクトリストに隠す
const long z_order=0) // マウスクリックの優先順位
{
//--- 設定されてない場合アンカーポイントの座標を設定する
ChangeBitmapEmptyPoint(time,price);
//--- エラー値をリセットする
ResetLastError();
//--- ビットマップを作成する
if(!ObjectCreate(chart_ID,name,OBJ_BITMAP,sub_window,time,price))
{
Print(__FUNCTION__,
": failed to create a bitmap in the chart window! Error code = ",GetLastError());
return(false);
}
//--- 画像へのパスを設定する
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": failed to load the image! Error code = ",GetLastError());
return(false);
}
//--- 画像の表示範囲を設定する。もし幅または高さの値が
//--- それぞれソース画像の幅と高さを超えた場合、
//--- 描画されない。反対の場合
//--- これらの値に対応する部分が描画される。
ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width);
ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height);
//--- 表示範囲に表示される画像の部分を設定する
//--- デフォルトの部分は、画像の左上の領域
//--- 値は、この領域からのシフトして画像の別の部分の表示を可能にする
ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset);
ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset);
//--- オブジェクトのハイライト表示モードが有効になっている際の境界線の色を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- オブジェクトのハイライト表示モードが有効になっている際の境界線のスタイルを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- オブジェクトを移動するためのアンカーポイントのサイズを設定する
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,point_width);
//--- 前景（false）または背景（true）に表示
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- マウスでラベルを移動させるモードを有効（true）か無効（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- オブジェクトリストのグラフィックオブジェクトを非表示（true）か表示（false）にする
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- チャートのマウスクリックのイベントを受信するための優先順位を設定する
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ビットマップに新しい画像を設定する |
//+------------------------------------------------------------------+
bool BitmapSetImage(const long chart_ID=0, // チャート識別子
const string name="Bitmap", // ビットマップ名
const string file="") // ファイルパス
{
//--- エラー値をリセットする
ResetLastError();
//--- 画像へのパスを設定する
if(!ObjectSetString(chart_ID,name,OBJPROP_BMPFILE,file))
{
Print(__FUNCTION__,
": failed to load the image! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| チャートのビットマップを移動する |
//+------------------------------------------------------------------+
bool BitmapMove(const long chart_ID=0, // チャート識別子
const string name="Bitmap", // ビットマップ名
datetime time=0, // アンカーポイントの時刻
double price=0) // アンカーポイントの価格
{
//--- ポイントの位置が設定されていない場合、売値を有する現在足に移動する
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- エラー値をリセットする
ResetLastError();
//--- アンカーポイントを移動する
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": failed to move the anchor point! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ビットマップの表示範囲のサイズを変更する |
//+------------------------------------------------------------------+
bool BitmapChangeSize(const long chart_ID=0, // チャート識別子
const string name="Bitmap", // ビットマップ名
const int width=0, // ビットマップの幅
const int height=0) // ビットマップの高さ
{
//--- エラー値をリセットする
ResetLastError();
//--- ビットマップサイズを変更する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XSIZE,width))
{
Print(__FUNCTION__,
": failed to change the bitmap width! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YSIZE,height))
{
Print(__FUNCTION__,
": failed to change the bitmap height! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+--------------------------------------------------------------------+
//| 表示範囲の左上隅のy座標を変更する |
//+--------------------------------------------------------------------+
bool BitmapMoveVisibleArea(const long chart_ID=0, // チャート識別子
const string name="Bitmap", // ビットマップ名
const int x_offset=0, // 表示範囲の X 座標
const int y_offset=0) // 表示範囲の Y 座標
{
//--- エラー値をリセットする
ResetLastError();
//--- ビットマップの表示範囲の座標を変更する
if(!ObjectSetInteger(chart_ID,name,OBJPROP_XOFFSET,x_offset))
{
Print(__FUNCTION__,
": failed to change X coordinate of the visibility scope! Error code = ",GetLastError());
return(false);
}
if(!ObjectSetInteger(chart_ID,name,OBJPROP_YOFFSET,y_offset))
{
Print(__FUNCTION__,
": failed to change Y coordinate of the visibility scope! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| ビットマップを削除する |
//+------------------------------------------------------------------+
bool BitmapDelete(const long chart_ID=0, // チャート識別子
const string name="Bitmap") // ビットマップ名
{
//--- エラー値をリセットする
ResetLastError();
//--- ラベルを削除する
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": failed to delete a bitmap! Error code = ",GetLastError());
return(false);
}
//--- 実行成功
return(true);
}
//+------------------------------------------------------------------+
//| アンカーポイントの値をチェックして |
//| 空の物には初期値を設定する |
//+------------------------------------------------------------------+
void ChangeBitmapEmptyPoint(datetime &time,double &price)
{
//--- ポイントの時間が設定されていない場合、現在足になる
if(!time)
time=TimeCurrent();
//--- ポイントの価格が設定されていない場合、売値になる
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
}
//+------------------------------------------------------------------+
//| スクリプトプログラムを開始する関数 |
//+------------------------------------------------------------------+
void OnStart()
{
datetime date[]; // 表示されるバーを格納するための配列
double close[]; // 終値を格納するための配列
//--- ビットマップファイル名
string file="\\Images\\dollar.bmp";
//--- チャートウィンドウで表示されているバーの数
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- メモリ割り当て
ArrayResize(date,bars);
ArrayResize(close,bars);
//--- 日付配列に書き込む
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("Failed to copy time values! Error code = ",GetLastError());
return;
}
//--- 終値の配列に書き込む
if(CopyClose(Symbol(),Period(),0,bars,close)==-1)
{
Print("Failed to copy the values of Close prices! Error code = ",GetLastError());
return;
}
//--- 画像表示の頻度を定義する
int scale=(int)ChartGetInteger(0,CHART_SCALE);
//--- ステップを定義する
int step=1;
switch(scale)
{
case 0:
step=27;
break;
case 1:
step=14;
break;
case 2:
step=7;
break;
case 3:
step=4;
break;
case 4:
step=2;
break;
}
//--- 高値と安値のバーの値でビットマップを作成する（ギャップで）
for(int i=0;i<bars;i+=step)
{
//--- ビットマップを作成する
if(!BitmapCreate(0,"Bitmap_"+(string)i,0,date[i],close[i],InpFile,InpWidth,InpHeight,InpXOffset,
InpYOffset,InpColor,InpStyle,InpPointWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- スクリプトの動作が強制的に無効にされているかどうかをチェックする
if(IsStopped())
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//--- 半秒の遅れ
Sleep(500);
//--- 売りサインを削除する
for(int i=0;i<bars;i+=step)
{
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
if(!BitmapDelete(0,"Bitmap_"+(string)i))
return;
//--- チャートを再描画する
ChartRedraw();
// 0.05 秒の遅れ
Sleep(50);
}
//---
}
|
