Fragen von Neueinsteigern zu MQL4 und MQL5, Hilfe und Diskussion über Algorithmen und Codes

Tretyakov Rostyslav 2021.12.08 11:07 #18001

законопослушный гражданин #:

Entschuldigen Sie, dass ich es ein zweites Mal erwähne.

// Параметры советника
input string  sParametersEA = "";     // Параметры советника
input double  Lot           = 0.01;   // Количество лотов
input int     StopLoss      = 30;     // Уровень убытка
input int     TakeProfit    = 30;     // Уровень прибыли
input int     Slippage      = 3;      // Проскальзование (в пунктах)
input int     Magic         = 1;      // Индентификатор советника
input double  K_Martin1     = 2.0;    // Множитель мартин 1
input double  K_Martin2     = 2.0;    // Множитель мартин 2
input double  K_Martin3     = 2.0;    // Множитель мартин 3
input int     OrdersClose   = 5;      // Ограничение лотности мартин1
input int     OrdersClose2  = 5;      // Ограничение лотности мартин2
input int     DigitsLot     = 2;      // Точность лотности
// Параметры индикатора
input string  sParametersMA = "";     // Параметры индикатора
input int     PeriodMA      = 14;     // Период мувинга
input int     MovingShift   = 1;      // Сдвиг мувинга
// Глобальные переменные
string AC;
datetime Start, newbar;
double dMA;
double MaxMartinLot;
double MaxMartinLot2;
//+-----------------------------------------------------------------------------------------------+
int OnInit()
  {
Start          = TimeCurrent();
MaxMartinLot   = Lot*MathPow(1.4,OrdersClose);
MaxMartinLot2  = Lot*MathPow(K_Martin2,OrdersClose2);
AC             = StringConcatenate(" ", AccountCurrency());
return(INIT_SUCCEEDED);
  }
//+-----------------------------------------------------------------------------------------------+
void OnDeinit(const int reason)
  {

  }
//+-----------------------------------------------------------------------------------------------+
void OnTick()
  {
// Получим значение индикатора
   dMA = iMA(Symbol(), 0,PeriodMA, MovingShift, MODE_SMA, PRICE_CLOSE, 0); // MODE_SMA - простое усреднение , значение 0. PRICE_CLOSE- цена закрытия, значение 0.

// Если нет открытых ордеров, то входим в условие
      if(CountOrders()==0)
     {
// Если появился сигнал на покупку, то откроем ордер на покупку
      if(bSignalBuy() == true)
         vOrderOpenBuy();

// Если появился сигнал на продажу, то откроем ордер на продажу
      if(bSignalSell() == true)
         vOrderOpenSell();
     }
   }
//+-----------------------------------------------------------------------------------------------+
//|                                                             Функция проверки открытых оредров |
//+-----------------------------------------------------------------------------------------------+
int CountOrders() 
  {
   int cnt=0;
   int i=OrdersTotal()-1;
   for(int pos=i;pos>=0;pos--)
     {
      if(OrderSelect(pos, SELECT_BY_POS, MODE_TRADES))
        {
         if(OrderSymbol()==_Symbol)
           {
            if(OrderMagicNumber()==Magic) cnt++;
           }
        }
     }
   return(cnt);
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                             Функция поиска сигнала на покупку |
//+-----------------------------------------------------------------------------------------------+
bool bSignalBuy()
  {
   if(dMA > Open[1] && dMA < Close[1])  //Open[1] и Close[1]- цены открытия и закрытия каждого бара текущего графика.
      return(true);

   return(false);
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                             Функция поиска сигнала на продажу |
//+-----------------------------------------------------------------------------------------------+
bool bSignalSell()
  {
   if(dMA < Open[1] && dMA > Close[1])
      return(true);

   return(false);
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                            Функция открытия ордера на покупку |
//+-----------------------------------------------------------------------------------------------+
void vOrderOpenBuy()
  {
   if(newbar!=Time[0])
     {
   // Тикет ордера
      int iOTi = 0;   
   
      iOTi = OrderSend(Symbol(), OP_BUY, LOT(), Ask, Slippage, 0, 0, "", Magic, 0, clrNONE);
      
   // Проверим открылся ли ордер
      if(iOTi > 0)
   // Есди да, то выставим уровни убытка и прибыли
         vOrderModify(iOTi);
      else
   // Если нет, то получим ошибку
         vError(GetLastError());
      newbar=Time[0];
     }
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                            Функция открытия ордера на продажу |
//+-----------------------------------------------------------------------------------------------+
void vOrderOpenSell()
  {
   if(newbar!=Time[0])
     {
   // Тикет ордера  
      int iOTi = 0;   
   //Print(bCheckOrders());
      iOTi = OrderSend(Symbol(), OP_SELL, LOT(), Bid, Slippage, 0, 0, "", Magic, 0, clrNONE);
   
   // Проверим открылся ли ордер
      if(iOTi > 0)
   // Есди да, то выставим уровни убытка и прибыли
         vOrderModify(iOTi);
      else
   // Если нет, то получим ошибку
         vError(GetLastError());
      newbar=Time[0];
     }
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                                    Функция модификации ордера |
//+-----------------------------------------------------------------------------------------------+
void vOrderModify(int iOTi)
  {
   int    iOTy = -1;    // Тип ордера
   double dOOP = 0;     // Цена открытия ордера
   double dOSL = 0;     // Стоп Лосс
   int    iMag = 0;     // Идентификатор советника
   double dSL  = 0;     // Уровень убытка
   double dTP  = 0;     // Уровень прибыли

// Выберем по тикету открытый ордер, получим некоторые значения
   if(OrderSelect(iOTi, SELECT_BY_TICKET, MODE_TRADES))
     {
      iOTy = OrderType();
      dOOP = OrderOpenPrice();
      dOSL = OrderStopLoss();
      iMag = OrderMagicNumber();
     }

// Если ордер открыл данный советник, то входим в условие
   if(OrderSymbol() == Symbol() && OrderMagicNumber() == iMag)
     {
// Если Стоп Лосс текущего ордера равен нулю, то модифицируем ордер
      if(dOSL == 0)
        {
         if(iOTy == OP_BUY)
           {
            dSL = NormalizeDouble(dOOP - StopLoss * Point, Digits);
            dTP = NormalizeDouble(dOOP + TakeProfit * Point, Digits);

            bool bOM = OrderModify(iOTi, dOOP, dSL, dTP, 0, clrNONE);
           }

         if(iOTy == OP_SELL)
           {
            dSL = NormalizeDouble(dOOP + StopLoss * Point, Digits);
            dTP = NormalizeDouble(dOOP - TakeProfit * Point, Digits);

            bool bOM = OrderModify(iOTi, dOOP, dSL, dTP, 0, clrNONE);
           }
        }
     }
  }
//+-----------------------------------------------------------------------------------------------+
//|                                                                      Функция обработки ошибок |
//+-----------------------------------------------------------------------------------------------+
void vError(int iErr)
  {
   switch(iErr)
     {
      case 129:   // Неправильная цена
      case 135:   // Цена изменилась
      case 136:   // Нет цен
      case 138:   // Новые цены
         Sleep(1000);
         RefreshRates();
         break;

      case 137:   // Брокер занят
      case 146:   // Подсистема торговли занята
         Sleep(3000);
         RefreshRates();
         break;
     }
  }
//+-----------------------------------------------------------------------------------------------+
double LOT()
{
   int n=0;
   int m=0;
   int v=0;
   double OL=Lot;
   for (int j = OrdersHistoryTotal()-1; j >= 0; j--)
   {
      if (OrderSelect(j, SELECT_BY_POS,MODE_HISTORY))
      {
         if (OrderSymbol() == Symbol() && OrderMagicNumber() == Magic)
         {
            if (OrderProfit()>0) 
            {

               if (n==0) OL=NormalizeDouble(OrderLots()+K_Martin1,DigitsLot);
               n++;
               
               if ((OL>=MaxMartinLot)&& (m==0)) OL=NormalizeDouble(OrderLots()*K_Martin2,DigitsLot);
               m++;
               
               if ((OL>=MaxMartinLot2) && (v==0)) OL=NormalizeDouble(OrderLots()*K_Martin3,DigitsLot);
               v++;
            }
            else
            {
               if (n==0) {return(Lot);}
               else {return(OL);}
            }
         }
      }
   }
   
   return(OL);
}

Mihail Matkovskij #:

Dadurch wird das Signal verfehlt

законопослушный гражданин 2021.12.08 11:27 #18002

MakarFX #:
Das wird das Signal durchlassen.

Danke, ich werde beides ausprobieren.

Ivan Butko 2021.12.08 11:28 #18003

Bitte beraten Sie mich,

1. Multitest im MT5, wie ist er aufgebaut: jedes Paar nacheinander oder parallel, je nach Gesamtzeit (Nachahmung des realen Mehrwährungshandels)

2. Ist es in MT4 im Strategietester möglich, Indikatordaten eines anderen Währungspaares zu verwenden?

[ARCHIV] Alle Fragen von Fragen von Anfängern MQL5 Fehler, Irrtümer, Fragen

aleksan2021 2021.12.08 11:37 #18004

Könnten Sie mir bitte sagen, warum jedes Mal, wenn ich einen EA auf realen Ticks testen (Zeitrahmen und Broker ist die gleiche) das mt5-Terminal lädt die gleichen Daten vom Broker jedes Mal? Sollte mt5 diese Daten nicht einmal herunterladen und sie dann von meinem Computer herunterladen?

Fragen von Anfängern MQL5 [ARCHIV!] Alle Fragen von Hilfe bei der Codierung

законопослушный гражданин 2021.12.08 12:17 #18005

законопослушный гражданин #:

Danke, ich werde beides ausprobieren.

Beide Varianten funktionieren! Welche ist besser?)

Valeriy Yastremskiy 2021.12.08 12:22 #18006

Ivan Butko Mehrwährungshandels)

2. Ist es in MT4 im Strategietester möglich, Indikatordaten eines anderen Währungspaares zu verwenden?

2. Ja, aber die Daten der Paare sollten im Kursarchiv vorgeladen werden und sind nur ab dem Intervall verfügbar, das Sie geladen haben, denn die Daten der einzelnen TF sind unterschiedlich. Für 1-Minuten-Paare höchstens 5 Monate. Aufträge können nicht erteilt werden, aber es können Daten von Balken und damit von Indikatoren abgerufen werden. Auch Daten über Zecken sind nicht vorhanden.

lernen, wie man Geld Das EOP für Schulkinder. [WARNUNG GESCHLOSSEN!] Alle Fragen

Tretyakov Rostyslav 2021.12.08 12:23 #18007

законопослушный гражданин #:

Beide Autos funktionieren! Welches ist besser?)

Die Variante von Mikhail prüft das Signal nur am ersten Tick einer neuen Kerze, wenn das Signal später als der erste Tick ist, wird der Expert Advisor es verpassen.

законопослушный гражданин 2021.12.08 12:27 #18008

MakarFX #:
Die Variante von Mikhail prüft das Signal nur am ersten Tick einer neuen Kerze, wenn das Signal später als der erste Tick ist, wird der Expert Advisor es verpassen.

Der Test sollte also nach Michaels Version zu weniger Bestellungen im gleichen Zeitraum führen?

Tretyakov Rostyslav 2021.12.08 12:30 #18009

законопослушный гражданин #:

Der Test sollte also nach Michaels Version zu weniger Bestellungen im gleichen Zeitraum führen?

Wahrscheinlich.

Ivan Butko 2021.12.08 12:57 #18010

Valeriy Yastremskiy #:

2. Ja, aber diese Paare müssen vorab in das Kursarchiv geladen werden und stehen erst ab dem heruntergeladenen Intervall zur Verfügung, für jedes TF verschiedene Daten. Für einminütige Takte 5 Monate und normalerweise nicht mehr. Für jeden Auftrag können keine Aufträge erteilt werden, aber es können Daten von Balken und folglich von Indikatoren erhalten werden. Ich habe auch keine Tickdaten.

Danke

Fragen von Neueinsteigern zu MQL4 und MQL5, Hilfe und Diskussion über Algorithmen und Codes - Seite 1801