//+------------------------------------------------------------------+
//| Demo_iAO.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "Gösterge, iVolumes teknik göstergesi için tamponlardan"
#property description "nasıl veri alınacağını göstermektedir."
#property description "Göstergenin hesaplanmasında kullanılacak sembol ve periyot,"
#property description "symbol ve period parametreleri ile ayarlanır."
#property description "İşleyicinin oluşturulması yöntemi 'type' parametresi ile ayarlanır (fonksiyon tipi)."
#property indicator_separate_window
#property indicator_buffers 2
#property indicator_plots 1
//--- iAO grafiği
#property indicator_label1 "iAO"
#property indicator_type1 DRAW_COLOR_HISTOGRAM
#property indicator_color1 clrGreen,clrRed
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//+------------------------------------------------------------------+
//| İşleyici oluşturma yöntemleri için bir sayım |
//+------------------------------------------------------------------+
enum Creation
{
Call_iAO, // iAO kullan
Call_IndicatorCreate // IndicatorCreate kullan
};
//--- giriş parametreleri
input Creation type=Call_iAO; // fonksiyon tipi
input string symbol=" "; // sembol
input ENUM_TIMEFRAMES period=PERIOD_CURRENT; // zaman aralığı
//--- gösterge tamponları
double iAOBuffer[];
double iAOColors[];
//--- iAO göstergesinin değerlerini depolamak için bir değişken
int handle;
//--- kayıt için değişken
string name=symbol;
//--- çizelge üzerindeki gösterge ismi
string short_name;
//--- Awesome Oscillator göstergesindeki değerlerin sayısını koruyacağız
int bars_calculated=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function |
//+------------------------------------------------------------------+
int OnInit()
{
//--- dizilerin gösterge tamponlarına atanması
SetIndexBuffer(0,iAOBuffer,INDICATOR_DATA);
SetIndexBuffer(1,iAOColors,INDICATOR_COLOR_INDEX);
//--- göstergenin çizileceği sembolü ayarla
name=symbol;
//--- sağa ve sola doğru olan boşlukları sil
StringTrimRight(name);
StringTrimLeft(name);
//--- sonuçta 'name' dizgisi sıfır uzunluğa sahipse
if(StringLen(name)==0)
{
//--- göstergenin tutturulduğu çizelge sembolünü al
name=_Symbol;
}
//--- göstergenin tanıtıcı değerini oluştur
if(type==Call_iAO)
handle=iAO(name,period);
else
handle=IndicatorCreate(name,period,IND_AO);
//--- işleyici oluşturulmadıysa
if(handle==INVALID_HANDLE)
{
//--- hatayı belirt ve hata kodunu al
PrintFormat("iAO göstergesi, %s/%s sembolü için oluşturulamadı, hata kodu %d",
name,
EnumToString(period),
GetLastError());
//--- gösterge erken durduruldu
return(INIT_FAILED);
}
//--- Awesome Oscillator göstergesinin hesaplandığı sembol ve zaman aralığı değerlerini göster
short_name=StringFormat("iAO(%s/%s)",name,EnumToString(period));
IndicatorSetString(INDICATOR_SHORTNAME,short_name);
//--- göstergenin normal yolla başlatılması
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
//--- iAO göstergesinden kopyalanan değerlerin sayısı
int values_to_copy;
//--- göstergede hesaplanan değerlerin sayısını belirle
int calculated=BarsCalculated(handle);
if(calculated<=0)
{
PrintFormat("BarsCalculated() %d dönüşü yaptı, hata kodu %d",calculated,GetLastError());
return(0);
}
//--- bu, gösterge değerlerinin ilk hesaplanması ise veya iAO göstergesinin değerleri değiştiyse
//--- veya göstergeyi iki veya daha fazla çubuk için hesaplamak gerekiyorsa (yani fiyat geçmişi değiştiyse)
if(prev_calculated==0 || calculated!=bars_calculated || rates_total>prev_calculated+1)
{
//--- verilen sembol ve periyot için iAOBuffer dizisinin büyüklüğü iAO göstergesinin değerlerinden fazlaysa, her şeyi kopyalamayacağız
//--- Aksi durumda, gösterge tamponlarının büyüklüklerinden daha az kopyalama yaparız
if(calculated>rates_total) values_to_copy=rates_total;
else values_to_copy=calculated;
}
else
{
//--- Bu, gösterge değerlerinin daha önce hesaplandığı anlamına geliyor OnCalculate() fonksiyonu daha önce çağrılmış)
//--- hesaplama için bir çubuktan fazlası eklenmeyecek
values_to_copy=(rates_total-prev_calculated)+1;
}
//--- iAOBuffer ve iAOColors dizilerini, Awesome Oscillator indicator göstergesinin değerleriyle alınmış
//--- FillArraysFromBuffer fonksiyonu false dönüşü yaparsa, bilgi henüz kullanılabilir değildir, çık
if(!FillArraysFromBuffer(iAOBuffer,iAOColors,handle,values_to_copy)) return(0);
//--- mesajı oluştur
string comm=StringFormat("%s ==> göstergedeki gncellenen değer %s: %d",
TimeToString(TimeCurrent(),TIME_DATE|TIME_SECONDS),
short_name,
values_to_copy);
//--- servis mesajını çizelgede göster
Comment(comm);
//--- Accelerator Oscillator göstergesindeki değerlerin sayısını hatırla
bars_calculated=calculated;
//--- bir sonraki çağrı için prev_calculated değerine dönüş yap
return(rates_total);
}
//+------------------------------------------------------------------+
//| iAO göstergesi ile, gösterge tamponlarının doldurulması |
//+------------------------------------------------------------------+
bool FillArraysFromBuffer(double &values[], // Awesome Oscillator değerleri için gösterge tamponu
double &color_indexes[], // renk tamponu (renk indislerini depolamak için)
int ind_handle, // iAO göstergesinin tanıtıcı değeri
int amount // kopyalanan değerlerin sayısı
)
{
//--- hata kodunu sıfırla
ResetLastError();
//--- iAOBuffer dizisinin bir kısmını 0 indisli tamponun değerleriyle doldur
if(CopyBuffer(ind_handle,0,0,amount,values)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("iAO göstergesinin verileri kopyalanamadı, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- renk indislerini kopyala
if(CopyBuffer(ind_handle,1,0,amount,color_indexes)<0)
{
//--- kopyalama başarısız ise hata kodu al
PrintFormat("iAO göstergesinden renk değerlerinin kopyalanması başarısız oldu, hata kodu %d",GetLastError());
//--- sıfır sonuç ile çık - gösterge hesaplanmamış sayılacak
return(false);
}
//--- herşey yolunda
return(true);
}
//+------------------------------------------------------------------+
//| Indicator deinitialization function |
//+------------------------------------------------------------------+
void OnDeinit(const int reason)
{
if(handle!=INVALID_HANDLE)
IndicatorRelease(handle);
//--- göstergeyi sildikten sonra çizelgeyi temizle
Comment("");
}
|