Assistente MQL5 - Sinais de Negociação Baseado em 3 Corvos Negros/3 Soldados Brancos + Estocástico - expert para MetaTrader 5

O Assistente MQL5 permite a criação de Expert Advisors prontos para usar com base nas classes da Biblioteca Padrão entregues juntamente com o terminal do cliente (veja Criando Expert Advisors Prontos Para Usar no Assistente MQL5 para mais detalhes). Ele permite verificar suas idéias de negociação rapidamente, tudo que você precisa é criar sua própria classe de sinais de negociação. A estrutura desta classe e exemplo podem ser encontrado no artigo Assistente MQL5: Como criar um módulo de sinais de negociação.

A idéia em geral é a seguinte: a classe dos sinais de negociação deriva de CExpertSignal, no próximo passo, é necessário substituir os métodos virtuais LongCondition() e ShortCondition() com seus próprios métodos.

Há um livro chamado "Estratégias dos melhores traders" (em Russo), existem muitas estratégias de negociação que são considerados neste livro, vamos nos concentrar em padrões de velas de reversão, confirmados pelos osciladores Stochastic, CCI, MFI e RSI.

A melhor maneira é criar a classe separada, derivado de CExpertSignal para a verificação da formação de padrões de candles. Para confirmar os sinais de negociação, gerados por padrões de velas, apenas escreva a classe derivada de CCandlePattern e adicionar aos recursos necessários existentes(por exemplo, a confirmação por osciladores).

Aqui vamos considerar os sinais, com base nos padrões candles de reversão "3 Corvos Negros/3 Soldados Brancos", confirmados pelo indicador Estocástico. O módulo de sinais de negociação baseia-se na classe CCandlePattern, é um simples exemplo de seu uso para a criação de sinais de negociação com padrões de candles.

1. Padrão candle de reversão "3 Corvos Negros" e "3" Soldados Brancos

1.1. Padrão Candle 3 Corvos Negros

Uma padrão candle baixista é usado para prever a reversão da tendência de alta. Este padrão é constituído por três candles longos encorpados consecutivos que fecharam no preço abaixo do dia anterior em cada sessão aberta e que ocorre dentro do corpo da candle anterior.

Figura 1. Padrão candles "3 Corvos Negros"

O reconhecimento do padrão "3 Corvos Negros" é implementado no método CheckPatternThreeBlackCrows da classe CCandlePattern:

//+------------------------------------------------------------------+
//| Verificar a formação do padrão de candles "3 Corvos Negros"      |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeBlackCrows()
  {
//--- 3 Corvos Negros 
   if((Open(3)-Close(3)>AvgBody(1)) && // (candles negros longos)
      (Open(2)-Close(2)>AvgBody(1)) &&
      (Open(1)-Close(1)>AvgBody(1)) && 
      (MidPoint(2)<MidPoint(3))     && // (pontos médios mais elevados)
      (MidPoint(1)<MidPoint(2)))       
      return(true);
//---
   return(false);
  }

1.2. Padrão Candle 3 Soldados Brancos

Uma candle de alta é usado para prever a reversão da tendência de baixa em vigor. Este padrão é constituído por três candles longos encorpados consecutivos que fecharam no preço abaixo do dia anterior em cada sessão aberta e que ocorre dentro do corpo da candle anterior.

O padrão é válido, desde que a candle do segundo dia se abra na metade superior de um dia de intervalo. No final do segundo dia, deve fechar-se perto da sua altura, deixando uma muito pequena ou inexistente sombra superior. O mesmo padrão é repetido no terceiro dia.

Figura 2. Padrão candle "3 Soldados Brancos"

Aqui está o método de reconhecimento do padrão "3 Soldados Brancos":

//+------------------------------------------------------------------+
//| Verificar a formação do padrão de candles "3 Soldados Brancos"   |
//+------------------------------------------------------------------+
bool CCandlePattern::CheckPatternThreeWhiteSoldiers()
  {
   //--- 3 Soldados Brancos
   if((Close(3)-Open(3)>AvgBody(1)) && // candles brancos longos
      (Close(2)-Open(2)>AvgBody(1)) &&
      (Close(1)-Open(1)>AvgBody(1)) &&
      (MidPoint(2)>MidPoint(3))     && // pontos médios mais elevados
      (MidPoint(1)>MidPoint(2)))
      return(true);
//---
   return(false);
  }

2. Sinais de negócios confirmados pelo indicador Estocástico

Os sinais de negociação para abrir posição vendida ou comprada deve ser confirmado pelo oscilador Estocástico . A linha do sinal %D deve ser maior/menor correspondendo aos níveis críticos (30 ou 70).

O fechamento de uma posição aberta depende dos valores do indicador %D. Pode ser feito em dois casos:

1. se a linha %D atingiu o nível crítico oposto (80 para a posição comprada e 20 para posição vendida)
2. se o sinal inverso não é confirmado (quando a linha %D atinge os seguintes níveis: 20 para a posição comprada e 80 para a posição vendida)
   

Fig. 3. Padrão "3 Soldados Brancos", confirmado pelo indicador Estocástico

A verificação das condições de negociação para as entradas e saídas é implementada em dois métodos:

• int CBC_WS_Stoch::LongCondition() - verifica as condições para abrir posição comprada (retorna 80) e fecha aposição vendida (retorna 40);
  
• int CBC_WS_Stoch::ShortCondition() - verifica as condições para abrir posição vendida (retorna 80) e fecha posição vendida (retorna 40).

2.1. Abrir posição comprada/ Fechar posição vendida

1. A formação do padrão "Três Soldados Brancos" deve ser confirmado pelo indicador Estocástico: StochSignal(1)<30 (o valor da linha de sinal do indicador Estocástico da última barra fechada deve ser inferior a 30).

2. A posição vendida deve ser fechada se a linha de sinal do indicador Estocástica cruzou para cima os níveis 20 ou 80.

//+------------------------------------------------------------------+
//| Verificar condições de entrada e saída do mercado                |
//| 1) Entrada no Mercado (abrir posição comprada resultado=80)      |
//| 2) Saída do Mercado (fechar posição vendida, resultado=40)       |
//+------------------------------------------------------------------+
int CBC_WS_Stoch::LongCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de trabalho Expert Advisor 
//--- idx=0 - neste caso EA verifica as condições de comércio em cada tick 
//--- idx=1 - neste caso o EA verifica a negociação apenas em novas barras
   int idx   =StartIndex();
//--- verificação das condições para abrir posição comprada
//--- formação do padrão 3 Soldados Brancos e linha do sinal<30
  if (CheckCandlestickPattern(CANDLE_PATTERN_THREE_WHITE_SOLDIERS) && (StochSignal(1)<30))
     result=80;
//--- verificação das condições para fechar posição vendida
//--- linha de sinal do cruzamento de níveis sobrecomprado/sobrevendido ( para baixo de 80, para cima de 20) 
   if((((StochSignal(1)>20) && (StochSignal(2)<20)) ||
       ((StochSignal(1)>80) && (StochSignal(2)<80))))
     result=40;
//--- retorna o resultado
   return(result);
  }

2.2. Abrir posição vendida/ Fechar posição comprada

1. A formação de padrão "3 Corvos Negros" deve ser confirmado pelo indicador Estocástico: StochSignal(1)>70 (o valor da linha de sinal do indicador estocástico da última barra fechada deve ser maior do que 70).

2. A posição de compra deve ser fechada se a linha de sinal do indicador Estocástico cruza para baixo dos níveis 80 ou 20 .

//+------------------------------------------------------------------+
//| Verificar as condições de entrada e saída do mercado             |
//| 1) entrada no mercado (abrir posição vendida, resultado = 80)    |
//| 2) saída do mercado (fechar posição comprada, resultado = 40)    |
//+------------------------------------------------------------------+
int CBC_WS_Stoch::ShortCondition()
  {
   int result=0;
//--- idx pode ser usado para determinar o modo de trabalho Expert Advisor 
//--- idx=0 - neste caso EA verifica as condições de comércio em cada tick 
//--- idx=1 - neste caso o EA verifica a negociação apenas em novas barras
   int idx   =StartIndex();
//--- verificação de condições para abrir posição vendida
//--- formação do padrão 3 Corvos Pretos e linha de sinal>70
  if (CheckCandlestickPattern(CANDLE_PATTERN_THREE_BLACK_CROWS) && (StochSignal(1)>70))
     result=80;
//--- Verificação das condições para fechar posição comprada 
//--- linha de sinal do cruzamento dos níveis sobrecomprado/sobrevendido(para baixo de 80, para cima de 20) 
   if((((StochSignal(1)<80) && (StochSignal(2)>80)) ||
       ((StochSignal(1)<20) && (StochSignal(2)>20))))
     result=40;
//--- Retorna o Resultado
   return(result);
  }

2.3. Criando Expert Advisor usando Assistente MQL5

Para criar um Expert Advisor através do Assistente MQL5:

Fig. 4. Criando Expert Advisor usando Assistente MQL5

Vamos especificar o nome do Expert Advisor:

Fig. 5. Propriedades gerais do Expert Advisor

Depois disso, precisamos selecionar os módulos de sinais de negociação a serem usados.

Fig. 6. Propriedades de sinal do Expert Advisor

No nosso caso, usamos apenas um módulo de sinais de negociação.

Adicionando os módulo de sinais de negociação "Sinais baseado em 3 Corvos Preto/3 Soldados Brancos confirmados por Estocástico":

Fig. 7. Propriedades de sinal do Expert Advisor

Módulo de sinais de negociação adicionado:

Fig. 8. Propriedades de sinal do Expert Advisor

Você pode selecionar as propriedades à direita, mas vamos utilizar a opção "trailing stop não usado":

Fig. 9. Seguindo as propriedades do Expert Advisor

Em relação às propriedades de gerenciamento de dinheiro, utilisaremos a opção "Negociação com volume de negociação fixo":

Fig. 10. Propriedades de gerenciamento de dinheiro do Expert Advisor

Ao pressionar o botão "Finish", vamos obter o código do Expert Advisor que foi gerado, localizada em Expert_ABC_WS_Stoch.mq5, ele será salvo em terminal_data_folder\MQL5\Experts\.

Os parâmetros de entrada padrão do Expert Advisor que foi gerado são:

//--- Entrada para o sinal principal 
input int            Signal_ThresholdOpen   =10;     // Valor limite de sinal para abrir [0...100]
input int            Signal_ThresholdClose  =10;     // Valor limite de sinal para fechar[0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para executar uma oferta
input double         Signal_StopLevel       =50.0;   // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =50.0;   // Nível de Take Profit (em pontos)

deve ser substituído para:

//--- Entrada para o sinal principal
input int            Signal_ThresholdOpen   =40;     // Valor limite de sinal para abrir [0...100]
input int            Signal_ThresholdClose  =20;     // Valor limite de sinal para fechar [0...100]
input double         Signal_PriceLevel      =0.0;    // Nível do preço para executar uma oferta 
input double         Signal_StopLevel       =0.0;    // Nível de Stop Loss (em pontos)
input double         Signal_TakeLevel       =0.0;    // Nível de Take Profit(em pontos)

Os parâmetros de entrada Signal_ThresholdOpen/Signal_ThresholdClose permitem especificar os níveis de limite para abrir e fechar de posições.

No código dos métodos LongCondition() e ShortCondition() da classe de sinais de negociação colocaremos os valores fixos do limite:

• Abrir Posição: 80;
• Fechar posição: 40.
  

Os valores dos parâmetros de entrada Signal_StopLevel e Signal_TakeLevel são definidos como 0, isso significa que o fechamento das posições será realizado apenas quando as condições de fechamento forem verdadeiras.

2.4. Teste dos resultos pelo histórico

Vamos considerar os testes do Expert Advisor em dados históricos (EURUSD H1, testando nos períodos: 2010.01.01-2011.02.02, PeriodK=47, PeriodD=9, PeriodSlow=13, MA_period=5).

Na criação de Expert Advisor usamos o volume fixo (Lote da Negociação Fixa, 0.1), o algorítimo do Trailing Stop não é usado (Trailing Stop não é usado).

Fig. 11. Os resultados dos testes do Expert Advisor com base em 3 Corvos Negros/3 Soldados Brancos + Estocástico "

O melhor conjunto de parâmetros de entrada podem ser encontrados usando o Testador de Estratégias do terminal do cliente MetaTrader 5.

O código do Expert Advisor, criado pelo Assistente MQL5 está anexado em expert_abc_ws_stoch.mq5.