//+------------------------------------------------------------------+
//| DRAW_COLOR_LINE.mq5 |
//| Copyright 2000-2024, MetaQuotes Ltd. |
//| https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link "https://www.mql5.com"
#property version "1.00"
#property description "DRAW_COLOR_LINE을 시연하기 위한 지표"
#property description "종가에 각각 20개의 색상 조각으로 선을 그립니다"
#property description "선의 너비, 스타일 및 색상이 임의로 변경됩니다"
#property description "모든 N 틱"
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots 1
//--- ColorLine 플롯
#property indicator_label1 "ColorLine"
#property indicator_type1 DRAW_COLOR_LINE
//--- 각 컬러링 막대를 위한 5가지 색상 정의 (특수 배열에 저장됨)
#property indicator_color1 clrRed,clrBlue,clrGreen,clrOrange,clrDeepPink // (최대 64 색을 지정할 수 있습니다)
#property indicator_style1 STYLE_SOLID
#property indicator_width1 1
//--- 매개변수 입력
input int N=5; //변경할 틱의 수
input int Length=20; // 막대에서 각 색상 부분의 길이
int line_colors=5; // The number of set colors is 5 - see #property indicator_color1
//--- 플로팅할 버퍼
double ColorLineBuffer[];
//--- 각 막대에 선 색상을 저장하는 버퍼
double ColorLineColors[];
//--- 색상을 저장하는 배열에는 7가지 요소가 포함됩니다
color colors[]={clrRed,clrBlue,clrGreen,clrChocolate,clrMagenta,clrDodgerBlue,clrGoldenrod};
//--- 선 스타일을 저장할 배열
ENUM_LINE_STYLE styles[]={STYLE_SOLID,STYLE_DASH,STYLE_DOT,STYLE_DASHDOT,STYLE_DASHDOTDOT};
//+------------------------------------------------------------------+
//| 사용자 지정 지표 초기화 함수 |
//+------------------------------------------------------------------+
int OnInit()
{
//--- 지표 버퍼 및 배열 바인딩
SetIndexBuffer(0,ColorLineBuffer,INDICATOR_DATA);
SetIndexBuffer(1,ColorLineColors,INDICATOR_COLOR_INDEX);
//--- 모조 난수 생성기 초기화
MathSrand(GetTickCount());
//---
return(INIT_SUCCEEDED);
}
//+------------------------------------------------------------------+
//| 사용자 지정 지표 반복 함수 |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
const int prev_calculated,
const datetime &time[],
const double &open[],
const double &high[],
const double &low[],
const double &close[],
const long &tick_volume[],
const long &volume[],
const int &spread[])
{
static int ticks=0;
//--- 틱을 계산하여 선의 스타일, 색상 및 너비 변경
ticks++;
//--- 틱의 임계 수가 누적된 경우
if(ticks>=N)
{
//--- 선 속성 변경
ChangeLineAppearance();
//--- 선 섹션의 색상 변경
ChangeColors(colors,5);
//--- 틱 카운터를 0으로 재설정
ticks=0;
}
//--- 지표 값 계산을 위한 블록
for(int i=0;i<rates_total;i++)
{
//--- 버퍼에 지표 값 쓰기
ColorLineBuffer[i]=close[i];
//--- 이제, 이 막대의 색상 인덱스를 임의로 설정
int color_index=i%(5*Length);
color_index=color_index/Length;
//--- 이 막대의 경우, 선은 인덱스 color_index인 색상을 가집니다
ColorLineColors[i]=color_index;
}
//--- 함수의 다음 호출에 대해 prev_calculated 값을 반환
return(rates_total);
}
//+------------------------------------------------------------------+
//| 선 세그먼트의 색상을 변경 |
//+------------------------------------------------------------------+
void ChangeColors(color &cols[],int plot_colors)
{
//--- 색상의 수
int size=ArraySize(cols);
//---
string comm=ChartGetString(0,CHART_COMMENT)+"\r\n\r\n";
//--- 각 색상 인덱스에 대해 임의로 새 색상 정의
for(int plot_color_ind=0;plot_color_ind<plot_colors;plot_color_ind++)
{
//--- 임의 값 가져오기
int number=MathRand();
//--- col[] 배열의 인덱스를 정수 나눗셈의 나머지 항목으로 가져오기
int i=number%size;
//--- 각 인덱스의 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0, // 그래픽 스타일의 수
PLOT_LINE_COLOR, // 속성 식별자
plot_color_ind, // 색의 인덱스, 색상을 쓰는 곳
cols[i]); // 새 색상
//--- 색상 쓰기
comm=comm+StringFormat("LineColorIndex[%d]=%s \r\n",plot_color_ind,ColorToString(cols[i],true));
ChartSetString(0,CHART_COMMENT,comm);
}
//---
}
//+------------------------------------------------------------------+
//| 지표에 표시된 선의 모양을 변경 |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
{
//--- 라인 속성에 대한 정보를 구성하기 위한 문자열
string comm="";
//--- 선 너비 변경 블록
int number=MathRand();
//--- 정수 나눗셈의 나머지 너비 가져오기
int width=number%5; // 너비는 0 ~ 4로 설정됩니다
//--- 색상을 PLOT_LINE_WIDTH 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- 선 너비 쓰기
comm=comm+" Width="+IntegerToString(width);
//--- 선의 스타일을 변경하기 위한 블록
number=MathRand();
//--- 제수는 스타일 배열의 크기와 같습니다
int size=ArraySize(styles);
//--- 정수 나눗셈의 나머지 항목으로 새 스타일을 선택할 인덱스를 가져오기
int style_index=number%size;
//--- 색상을 PLOT_LINE_COLOR 속성으로 설정
PlotIndexSetInteger(0,PLOT_LINE_STYLE,styles[style_index]);
//--- 선 스타일 쓰기
comm=EnumToString(styles[style_index])+", "+comm;
//--- 설명을 사용하여 차트에 정보 표시
Comment(comm);
}
|
