//--- 설명
#property description "스크립트는 \"각도별 추세선\" 그래픽 개체를 그립니다."
#property description "고정점 좌표는 다음 크기의 백분율로 설정됩니다"
#property description "차트 창."
//--- 스크립트 실행 중 입력 매개변수의 표시 창
#property script_show_inputs
//--- 스크립트의 입력 매개변수
input string InpName="Trend"; // 선 이름
input int InpDate1=50; // 첫 번째 점 날짜(%)
input int InpPrice1=75; // 첫 번째 점 가격(%)
input int InpAngle=0; // 선 기울기 각도
input color InpColor=clrRed; // 선 색상
input ENUM_LINE_STYLE InpStyle=STYLE_DASH; // 선 스타일
input int InpWidth=2; // 선 너비
input bool InpBack=false; // 배경 선
input bool InpSelection=true; // 이동하려면 강조 표시
input bool InpRayLeft=false; // 좌측으로 선 연장
input bool InpRayRight=true; // 우측으로 선 연장
input bool InpHidden=true; // 개체 목록에 숨겨짐
input long InpZOrder=0; // 마우스 클릭 우선 순위
//+------------------------------------------------------------------+
//| 각도별 추세선 생성 |
//+------------------------------------------------------------------+
bool TrendByAngleCreate(const long chart_ID=0, // �Q트의 ID
const string name="TrendLine", // line name
const int sub_window=0, // 하위 창 인덱스
datetime time=0, // 점 시간
double price=0, // 점 가격
const double angle=45.0, // 기울기 각도
const color clr=clrRed, // 선 색상
const ENUM_LINE_STYLE style=STYLE_SOLID, // 선 스타일
const int width=1, // 선 너비
const bool back=false, // 배경에
const bool selection=true, // 이동하려면 강조 표시
const bool ray_left=false, // 좌측으로 선 연장
const bool ray_right=true, // 우측으로 선 연장
const bool hidden=true, // 개체 목록에 숨겨짐
const long z_order=0) // 마우스 클릭 우선 순위
{
//--- 마우스로 추세선을 쉽게 끌 수 있는 두 번째 점 생성
datetime time2=0;
double price2=0;
//--- 고정점이 설정되지 않은 경우 고정점의 좌표 설정
ChangeTrendEmptyPoints(time,price,time2,price2);
//--- 오류 값 재설정
ResetLastError();
//--- 두 점을 사용하여 추세선 생성
if(!ObjectCreate(chart_ID,name,OBJ_TRENDBYANGLE,sub_window,time,price,time2,price2))
{
Print(__FUNCTION__,
": 추세선 생성 실패! Error code = ",GetLastError());
return(false);
}
//--- 두 번째 좌표, 각도 변경 시 추세선의 기울기 각도 변경
//--- 선의 점은 각도의 새 값에 따라 자동으로 재정의됩니다
ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle);
//--- 선 색상 설정
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- 선 스타일 설정
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- 선 굵기 설정
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- 전경(false) 또는 배경(true)에 표시
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- 마우스를 사용하여 선을 이동하는 모드를 활성화(true) 또는 비활성화(false)
//--- ObjectCreate 함수를 사용하여 그래픽 개체를 만드는 경우 개체는
//--- 기본적으로 강조 표시되고 이동됩니다. 이 메서드 내에서 선택 매개변수
//--- 기본적으로 true이므로 개체를 강조 표시하고 이동할 수 있습니다.
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- 선 디스플레이의 좌측 연속 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_LEFT,ray_left);
//--- 선 디스플레이의 우측 연속 모드를 활성화(true) 또는 비활성화(false)
ObjectSetInteger(chart_ID,name,OBJPROP_RAY_RIGHT,ray_right);
//--- 개체 목록에서 그래픽 개체 이름 숨기기(true) 또는 표시(false)
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- 차트에서 마우스 클릭 이벤트 수신 우선 순위 설정
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 추세선 고정점 좌표 변경 |
//+------------------------------------------------------------------+
bool TrendPointChange(const long chart_ID=0, // 차트의 ID
const string name="TrendLine", // 선 이름
datetime time=0, // 고정점 시간 좌표
double price=0) // 고정점 가격 좌표
{
//--- 포인트 위치가 설정되지 않은 겨우 입찰 가격이 있는 현재 막대로 이동합니다
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 오류 값 재설정
ResetLastError();
//--- 추세선 고정점 이동
if(!ObjectMove(chart_ID,name,0,time,price))
{
Print(__FUNCTION__,
": 고정점 이동 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 추세선 기울기 각도 변경 |
//+------------------------------------------------------------------+
bool TrendAngleChange(const long chart_ID=0, // 차트의 ID
const string name="TrendLine", // 추세선 이름
const double angle=45) // 추세선 기울기 각도
{
//--- 오류 값 재설정
ResetLastError();
//--- 추세 선 경사각 변경
if(!ObjectSetDouble(chart_ID,name,OBJPROP_ANGLE,angle))
{
Print(__FUNCTION__,
": 선 기울기 각도 변경 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 추세선 삭제 |
//+------------------------------------------------------------------+
bool TrendDelete(const long chart_ID=0, // 차트의 ID
const string name="TrendLine") // 선 이름
{
//--- 오류 값 재설정
ResetLastError();
//--- 추세선 삭제
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
": 추세선 삭제 실패! Error code = ",GetLastError());
return(false);
}
//--- 실행 성공
return(true);
}
//+------------------------------------------------------------------+
//| 추세선의 고정점 값 확인 기본값 설정 |
//| 빈 곳의 값 |
//+------------------------------------------------------------------+
void ChangeTrendEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- 첫 번째 점의 시간이 설정되지 않은 경우 현재 막대에 표시됩니다
if(!time1)
time1=TimeCurrent();
//--- 첫 번째 점의 가격이 설정되지 않은 경우 입찰 값을 갖습니다
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- 두 번째 보조점 좌표 설정
//--- 두 번째 점은 9 막대를 남기고 가격은 같습니다
datetime second_point_time[10];
CopyTime(Symbol(),Period(),time1,10,second_point_time);
time2=second_point_time[0];
price2=price1;
}
//+------------------------------------------------------------------+
//| 스크립트 프로그램 시작 함수 |
//+------------------------------------------------------------------+
void OnStart()
{
//--- 입력 매개변수의 정확성 확인
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100)
{
Print("오류! 입력 매개변수의 잘못된 값!");
return;
}
//--- 차트 창에 표시되는 막대 수
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- 가격 배열 크기
int accuracy=1000;
//--- 사용할 날짜 및 가격 값을 저장하기 위한 배열
//--- 선 고정점 좌표 설정 및 변경
datetime date[];
double price[];
//--- 메모리 할당
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- 날짜 배열 채우기
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("시간 값 복사 실패! Error code = ",GetLastError());
return;
}
//--- 가격 배열 채우기
//--- 차트의 최고값과 최저값을 찾기
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- 가격의 변경 단계를 정의 하고 배열 채우기
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- 선을 그리기 위한 점 지정
int d1=InpDate1*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
//--- 추세선 생성
if(!TrendByAngleCreate(0,InpName,0,date[d1],price[p1],InpAngle,InpColor,InpStyle,
InpWidth,InpBack,InpSelection,InpRayLeft,InpRayRight,InpHidden,InpZOrder))
{
return;
}
//--- 차트를 다시 그리고 1초 동안 대기
ChartRedraw();
Sleep(1000);
//--- 이제 선을 이동하고 회전합니다
//--- 루프 카운터
int v_steps=accuracy/2;
//--- 고정점을 이동하고 선의 경사각을 변경
for(int i=0;i<v_steps;i++)
{
//--- 다음의 값 사용
if(p1>1)
p1-=1;
//--- 점 이동
if(!TrendPointChange(0,InpName,date[d1],price[p1]))
return;
if(!TrendAngleChange(0,InpName,18*(i+1)))
return;
//--- 스크립트 작업이 강제로 비활성화 되었는지 확인
if(IsStopped())
return;
//--- 차트 다시 그리기
ChartRedraw();
}
//--- 1초 지연
Sleep(1000);
//--- 차트에서 삭제
TrendDelete(0,InpName);
ChartRedraw();
//--- 1초 지연
Sleep(1000);
//---
}
|
