MQL5 RiferimentoVariabili predefinite_AppliedTo

int _AppliedTo

La variaile _AppliedTo consente di trovare il tipo di dati, utilizzati per il calcolo dell'indicatore:

Tipo di dati	Senso	Descrizione dei dati utilizzati per il calcolo dell'indicatore.
—	0	L'indicatore usa la seconda forma di chiamata OnCalculate(): i dati per il calcolo non sono specificati da un determinato buffer o array di dati
Close	1	Prezzi Close
Open	2	Prezzi Open
High	3	Prezzi High
Low	4	Prezzi Low
Prezzo Mediano (HL/2)	5	Prezzo Mediano -- Median Price = (High+Low)/2
Prezzo Tipico (HLC/3)	6	Prezzo Tipico --Typical Price = (High+Low+Close)/3
Prezzo Ponderato (HLCC/4)	7	Prezzo Ponderato -- Weighted price = (Open+High+Low+Close)/4
Dati dell'indicatore precedente	8	Dati dell'indicatore, che è stato lanciato sul chart prima di questo indicatore
Dati del primo indicatore	9	Dati dell'indicatore, che è stato lanciato per primo sul chart
Handle dell'indicatore	10+	Dati dell'indicatore, che è stato passato alla funzione iCustom() usando l'handle dell'indicatore. Il valore _AppliedTo contiene l'handle dell'indicatore

Esempio:

//+------------------------------------------------------------------+
//| Funzione Inizializzazione Indicatore Custom                      |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- mappatura dei buffer degli indicatori
   SetIndexBuffer(0,Label1Buffer,INDICATOR_DATA);
// Ottenere il tipo di dati utilizzati per il calcolo dell'indicatore
   Print("_AppliedTo=",_AppliedTo);
   Print(getIndicatorDataDescription(_AppliedTo));
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Descrizione dei dati utilizzati per il calcolo dell'indicatore   |
//+------------------------------------------------------------------+
string getIndicatorDataDescription(int data_id)
  {
   string descr="";
   switch(data_id)
     {
      case(0):descr="È il primo tipo di OnCalculate() - nessun buffer di dati";
         break;
      case(1):descr="l' indicatore calcola sul prezzo Close";
         break;
      case(2):descr="l' indicatore calcola sul prezzo Open";
         break;
      case(3):descr="l' indicatore calcola sul prezzo High";
         break;
      case(4):descr="l' indicatore calcola sul prezzo Low";
         break;
      case(5):descr="l' indicatore calcola sul prezzo Median Price (HL/2)";
         break;
      case(6):descr="l' indicatore calcola sul prezzo Typical Price (HLC/3)";
         break;
      case(7):descr="l' indicatore calcola sul prezzo Weighted Price (HLCC/4)";
         break;
      case(8):descr="L'indicatore calcola i dati dell'indicatore precedente";
         break;
      case(9):descr="L'indicatore calcola i dati del Primo Indicatore";
         break;
      default: descr="L'indicatore calcola i dati dell'indicatore con handle="+string(data_id);
         break;
     }
//---
   return descr;
  }

Guarda anche

ENUM_APPLIED_PRICE

Variabili predefinite

_Digits