Toute question des nouveaux arrivants sur MQL4 et MQL5, aide et discussion sur les algorithmes et les codes.

[Artyom Trishkin]

Dans ce fil de discussion, je veux commencer à aider ceux qui veulent vraiment comprendre et apprendre la programmation dans le nouveau MQL4 et qui veulent passer facilement à MQL5 - les langages sont très similaires.

Ce blog sera un bon endroit pour discuter des problèmes, des algorithmes de leur solution et de toute autre question concernant la programmation MT d'une manière ou d'une autre.

J'espère que d'autres membres expérimentés de notre forum nous rejoindront et que ce fil de discussion sera intéressant pour tous.

[mila.com]

Bonjour.

Est-il possible de rendre le nombre de barres de construction dans l'indicateur Fractals standard personnalisable, c'est-à-dire différent de 5 ?

Si oui, comment faire ?

[Andrey F. Zelinsky]

mila.com:

Est-il possible de rendre le nombre de barres de construction dans l'indicateur Fractals standard personnalisable, c'est-à-dire différent de 5 ?

Si oui, comment faire ?

Vous ne pouvez pas le faire dans la version standard (terminal).

[Artyom Trishkin]

mila.com:

Bonjour.

Est-il possible de rendre le nombre de barres de construction dans l'indicateur Fractals standard personnalisable, c'est-à-dire différent de 5 ?

Si oui, comment faire ?

Comme Andrey vous l'a déjà dit, le modèle standard ne peut pas être utilisé, mais qu'est-ce qui vous empêche de fabriquer le vôtre ?

[Andrey F. Zelinsky]

le codebase a unhttps://www.mql5.com/ru/search#!keyword=fractals&module=mql5_module_codebase

[mila.com]

Andrey F. Zelinsky:
il y en a un dans le codebasehttps://www.mql5.com/ru/search#!keyword=fractals&module=mql5_module_codebase

Merci. J'en ai besoin juste pour mq4https://www.mql5.com/fr/code/1381

Je l'ai compilé dans l'éditeur MT4, il fonctionne, mais il charge le cpu, que dois-je changer pour ne pas le charger ?

//--- indicator buffers
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpFractals
#property indicator_label1  "Up Fractals"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot DnFractals
#property indicator_label2  "Down Fractals"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrTomato
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input int      InpLeftSide = 3;          // Кол-во баров слева от фрактала
input int      InpRightSide = 3;         // Кол-во баров справа от фрактала
//--- indicator buffers
double         UpFractalsBuffer[];
double         DnFractalsBuffer[];
//--- global variables
int            minRequiredBars;
int            leftSide, rightSide;
int            maxSide;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit() {
//---
   if ( InpLeftSide < 1 ) {
      leftSide = 2;
      printf("Неккоретно указан параметр \"Кол-во баров слева от фрактала\": %d. Будет использовано значение: %d.",
         InpLeftSide, leftSide);
   } else {
      leftSide = InpLeftSide;
   }
   if ( InpRightSide < 1 ) {
      rightSide = 2;
      printf("Неккоретно указан параметр \"Кол-во баров справа от фрактала\": %d. Будет использовано значение: %d.",
         InpRightSide, rightSide);
   } else {
      rightSide = InpRightSide;
   }
//---
   minRequiredBars = leftSide + rightSide + 1;
   maxSide = int(MathMax(leftSide, rightSide));
//---
   SetIndexBuffer(0, UpFractalsBuffer, INDICATOR_DATA);
   SetIndexBuffer(1, DnFractalsBuffer, INDICATOR_DATA);
//---
   PlotIndexSetInteger(0, PLOT_ARROW, 217);
   PlotIndexSetInteger(1, PLOT_ARROW, 218);
//---
   PlotIndexSetInteger(0, PLOT_ARROW_SHIFT, -10);  
   PlotIndexSetInteger(1, PLOT_ARROW_SHIFT, 10);
//---
   for ( int i = 0; i < 2; i++ ) {
      PlotIndexSetInteger(i, PLOT_DRAW_BEGIN, minRequiredBars);
      PlotIndexSetDouble(i, PLOT_EMPTY_VALUE, 0.0);
   }
//---
   IndicatorSetInteger(INDICATOR_DIGITS, _Digits);
//---
   IndicatorSetString(INDICATOR_SHORTNAME, "ffra ("+(string)leftSide+", "+(string)rightSide+")");
//---
   return(0);
}
//+------------------------------------------------------------------+
//| Check if is Up Fractal function                                  |
//+------------------------------------------------------------------+
bool isUpFractal(int bar, int max, const double &High[]) {
//---
   for ( int i = 1; i <= max; i++ ) {
      if ( i <= leftSide && High[bar] < High[bar-i] ) {
         return(false);
      }
      if ( i <= rightSide && High[bar] <= High[bar+i] ) {
         return(false);
      }
   }
//---
   return(true);  
}
//+------------------------------------------------------------------+
//| Check if is Down Fractal function                                |
//+------------------------------------------------------------------+
bool isDnFractal(int bar, int max, const double &Low[]) {
//---
   for ( int i = 1; i <= max; i++ ) {
      if ( i <= leftSide && Low[bar] > Low[bar-i] ) {
         return(false);
      }
      if ( i <= rightSide && Low[bar] >= Low[bar+i] ) {
         return(false);
      }
   }
//---
   return(true);  
}
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
{
//---
   int startBar, lastBar;
//---
   if ( rates_total < minRequiredBars ) {
      Print("Недостаточно данных для расчёта");
      return(0);
   }
//---
   if (prev_calculated < minRequiredBars) {
      startBar = leftSide;
      ArrayInitialize(UpFractalsBuffer, 0.0);
      ArrayInitialize(DnFractalsBuffer, 0.0);
   }        
   else {
      startBar = rates_total - minRequiredBars;
   }
//---
   lastBar = rates_total - rightSide;
   for ( int bar = startBar; bar < lastBar && !IsStopped(); bar++ ) {
      //---
      if ( isUpFractal(bar, maxSide, high) ) {
         UpFractalsBuffer[bar] = high[bar];
      } else {
         UpFractalsBuffer[bar] = 0.0;
      }
      //---
      if ( isDnFractal(bar, maxSide, low) ) {
         DnFractalsBuffer[bar] = low[bar];
      } else {
         DnFractalsBuffer[bar] = 0.0;
      }
   }  
//--- return value of prev_calculated for next call
   return(rates_total);
}
//+------------------------------------------------------------------+

[Artyom Trishkin]

mila.com:

Merci. Besoin d'un juste sur mq4https://www.mql5.com/en/code/1381

Les corrections sont minimes :

//+------------------------------------------------------------------+
//|                                              iXBarsFractals.mq4  |
//|               Copyright 2011, Rone. redaction 2016 by artmedia70 |
//|                                            [e-mail] |
//+------------------------------------------------------------------+
#property copyright "Copyright 2011, Rone."
#property link      "[e-mail]"
#property version   "1.00"
#property description "Индикатор позволяет отдельно указывать кол-во баров слева и справа от фрактала. Хорошо подходит "
#property description "для определения как локальных, так и глобальных экстремумов."
#property strict
//--- indicator buffers
#property indicator_chart_window
#property indicator_buffers 2
#property indicator_plots   2
//--- plot UpFractals
#property indicator_label1  "Up Fractals"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrDodgerBlue
#property indicator_style1  STYLE_SOLID
#property indicator_width1  1
//--- plot DnFractals
#property indicator_label2  "Down Fractals"
#property indicator_type2   DRAW_ARROW
#property indicator_color2  clrTomato
#property indicator_style2  STYLE_SOLID
#property indicator_width2  1
//--- input parameters
input int      InpLeftSide = 3;          // Кол-во баров слева от фрактала
input int      InpRightSide = 3;         // Кол-во баров справа от фрактала
//--- indicator buffers
double         UpFractalsBuffer[];
double         DnFractalsBuffer[];
//--- global variables
int            minRequiredBars;
int            leftSide,rightSide;
int            maxSide;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//---
   leftSide=(InpLeftSide<2?2:InpLeftSide);
   rightSide=(InpRightSide<2?2:InpRightSide);
//---
   minRequiredBars=leftSide+rightSide+1;
   maxSide=int(fmax(leftSide,rightSide));
//---
   SetIndexBuffer(0,UpFractalsBuffer,INDICATOR_DATA);
   SetIndexBuffer(1,DnFractalsBuffer,INDICATOR_DATA);
//---
   SetIndexArrow(0,217);
   SetIndexArrow(1,218);
   //PlotIndexSetInteger(0,PLOT_ARROW,217);
   //PlotIndexSetInteger(1,PLOT_ARROW,218);
//---
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,-10);
   PlotIndexSetInteger(1,PLOT_ARROW_SHIFT,10);
//---
   for(int i=0; i<2; i++) {
      PlotIndexSetInteger(i,PLOT_DRAW_BEGIN,minRequiredBars);
      PlotIndexSetDouble(i,PLOT_EMPTY_VALUE,0.0);
      }
//---
   IndicatorSetInteger(INDICATOR_DIGITS,_Digits);
//---
   IndicatorSetString(INDICATOR_SHORTNAME,"XBarsFractals("+(string)leftSide+", "+(string)rightSide+")");
//---
   return(0);
  }
//+------------------------------------------------------------------+
//| Check if is Up Fractal function                                  |
//+------------------------------------------------------------------+
bool isUpFractal(int bar,int max,const double &high[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && high[bar]<high[bar-i])     return(false);
      if(i<=rightSide && high[bar]<=high[bar+i])   return(false);
      }
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Check if is Down Fractal function                                |
//+------------------------------------------------------------------+
bool isDnFractal(int bar,int max,const double &low[])
  {
//---
   for(int i=1; i<=max; i++) {
      if(i<=leftSide && low[bar]>low[bar-i])    return(false);
      if(i<=rightSide && low[bar]>=low[bar+i])  return(false);
      }
//---
   return(true);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   int startBar,lastBar;
//---
   if(rates_total<minRequiredBars) return(0);
//---
   if(prev_calculated<minRequiredBars) {
      startBar=leftSide;
      ArrayInitialize(UpFractalsBuffer, 0.0);
      ArrayInitialize(DnFractalsBuffer, 0.0);
      }
   else startBar=rates_total-minRequiredBars;
//---
   lastBar=rates_total-rightSide;
   for(int bar=startBar; bar<lastBar && !IsStopped(); bar++) {
      //---
      if(isUpFractal(bar,maxSide,high))   UpFractalsBuffer[bar]=high[bar];
      else                                UpFractalsBuffer[bar]=0.0;
      //---
      if(isDnFractal(bar,maxSide,low))    DnFractalsBuffer[bar]=low[bar];
      else                                DnFractalsBuffer[bar]=0.0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+

C'est vrai, je le ferais un peu différemment, mais c'est la force de l'habitude...

Vous pourriez même le faire comme ça :

   leftSide=(InpLeftSide<1?1:InpLeftSide);
   rightSide=(InpRightSide<1?1:InpRightSide);

Alors vous obtiendrez des fractales assez amusantes...

[mila.com]

Artyom Trishkin:

Les corrections sont minimes :

Bien que je l'aurais fait un peu différemment, mais c'est la force de l'habitude...

Vous pourriez même le faire comme ça :

   leftSide=(InpLeftSide<1?1:InpLeftSide);
   rightSide=(InpRightSide<1?1:InpRightSide);

Dans ce cas, il affichera des fractales absolument ridicules...

Merci, comme ça.

PLOT_ARROW_SHIFT

Vous ne le trouvez pas non plus dans l'aide MT4, par quoi le remplacer ?

[Artyom Trishkin]

mila.com:

Merci, il y en a un comme ça.

PLOT_ARROW_SHIFT

Pas dans l'aide MT4 non plus, par quoi le remplacer ?

Il s'agit de "Vertical Arrow Offset for DRAW_ARROW Style".

Aucun des standards.

Vous pouvez simplement définir le décalage soit dans les paramètres, soit par la valeur de l'ATR.

Et faites ces lignes comme ceci :

//---
   for(int i=0; i<2; i++) {
      SetIndexDrawBegin(i,minRequiredBars);
      SetIndexEmptyValue(i,0);
      //PlotIndexSetInteger(i,PLOT_DRAW_BEGIN,minRequiredBars);
      //PlotIndexSetDouble(i,PLOT_EMPTY_VALUE,0.0);
      }
//---

Supprimez ce qui est commenté ici et mettez ce qui est commenté ici.

[mila.com]

Artyom Trishkin:

Il s'agit du "décalage vertical de la flèche pour le style DRAW_ARROW".

Effacez ce qui est commenté ici et mettez ce qui est écrit dedans.

C'est toujours en cours de chargement.

Appeler d'un autre indicateur, même accrocher le terminal pendant un moment.

Que puis-je faire d'autre ?

[Artyom Trishkin]

mila.com:

C'est toujours en cours de chargement.

Appeler d'un autre indicateur, même accrocher le terminal pendant un moment.

Que puis-je faire d'autre ?

N'appelez pas d'un autre indicateur :)

Ou montrez comment vous le faites.