DocumentationSections
Référence MQL5Indicateurs PersonnalisésIndicatorSetString 

IndicatorSetString

Spécifie la valeur de la propriété correspondante de l'indicateur. La propriété de l'indicateur doit être du type string. Il y a 2 variantes de la fonction.

L'appel avec l'indication de l'identificateur de la propriété.

L'appel avec l'indication de l'identificateur et le modificateur de la propriété.

bool  IndicatorSetString(
   int     prop_id,           // identificateur
   int     prop_modifier,     // modificateur 
   string  prop_value         // valeur établie
   )

Paramètres

prop_id

[in]  L'identificateur de la propriété de l'indicateur. La valeur peut être une des valeurs de l'énumération ENUM_CUSTOMIND_PROPERTY_STRING.

prop_modifier

[in]  Le modificateur  de la propriété indiquée. Seulement les propriétés des niveaux demandent le modificateur.

prop_value

[in]  La valeur de la propriété.

La valeur rendue

En cas de l'exécution réussie rend true, dans le cas contraire rend false.

Note

Le numérotage des propriétés (des modificateurs) à l'utilisation de la directive #property commence par 1 (une unité), pendant que la fonction utilise le numérotage par 0 (un zéro). Si le numéro du niveau était spécifié incorrectementl'affichage de l'indicateur peut se distinguer de celui qui est supposé.

Par exemple pour spécifier la description du premier niveau horizontal utilisez l'indice nul:

  • IndicatorSetString(INDICATOR_LEVELTEXT, 0, "First Level") - on utilise l'indice 0 pour spécifier la tâche de la description de texte du premier niveau.

L'exemple: l'indicateur qui établie les signatures vers les niveaux horizontaux de l'indicateur.

L'exemple de l'utilisation de la fonction IndicatorSetString()

#property indicator_separate_window
#property indicator_minimum 0
#property indicator_maximum 100
//--- spécifions la démonstration de trois niveaux horizontaux dans la fenêtre séparée de l'indicateur
#property indicator_level1 30
#property indicator_level2 50
#property indicator_level3 70
//---établissons la couleur des niveaux horizontaux
#property indicator_levelcolor clrRed
//--- établissons le style des niveaux horizontaux
#property indicator_levelstyle STYLE_SOLID
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- spécifions les descriptions des niveaux horizontaux
   IndicatorSetString(INDICATOR_LEVELTEXT,0,"First Level (index 0)");
   IndicatorSetString(INDICATOR_LEVELTEXT,1,"Second Level (index 1)");
   IndicatorSetString(INDICATOR_LEVELTEXT,2,"Third Level (index 2)");
//---spécifions le nom court de l'indicateur
   IndicatorSetString(INDICATOR_SHORTNAME,"IndicatorSetString() Demo");
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
//---
   
//--- return value of prev_calculated for next call
   return(rates_total);
  }

Voir aussi

Propriétés des indicateurs d'utilisateurs, Propriétés des programmes (#property)