Référence MQL5Indicateurs PersonnalisésStyles d'Indicateurs dans les ExemplesDRAW_ARROW

DRAW_ARROW

Le style DRAW_ARROW dessine les flèches sur le graphique par la couleur spécifiée (les symboles de l'ensemble Wingdings) selon la valeur du tampon d'indicateur. On peut spécifier l'épaisseur et la couleur des symboles de la meme façon que pour le style DRAW_LINE — par les directives du compilateur ou dynamiquement à l'aide de la fonction PlotIndexSetInteger(). Le changement dynamique des propriétés de la construction graphique permet de changer l'aspect de l'indicateur en fonction de la situation actuelle.

Le code du symbole pour la sortie sur le graphique est spécifié à l'aide de la propriété PLOT_ARROW.

//--- - spécifions le code du symbole de l'ensemble Wingdings pour le dessin dans PLOT_ARROW
PlotIndexSetInteger(0,PLOT_ARROW,code);

Par défaut la valeur PLOT_ARROW=159 (le cercle).

Chaque flèche représente en réalité le symbole, qui a la hauteur et le point du rattachement, et peut fermer par lui-même une certaine importante information sur le graphique (par exemple, le prix de la clôture de la barre). C'est pourquoi on peut spécifier en supplément un décalage vertical en pixels, qui ne dépend pas de l'échelle du graphique. Les flèches seront visuellement déplacées selon la verticale sur le nombre indiqué de pixels, bien que les valeurs de l'indicateur restent les mêmes:

//--- spécifions le décalage des flèches selon le vertical en pixels
PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);

La valeur négative PLOT_ARROW_SHIFT signifie le décalage des flèches en haut, la valeur positive déplace les flèches en bas.

On peut utiliser le style DRAW_ARROW dans une sous- fenêtre séparée du graphique, ainsi que dans une fenêtre principale. Les valeurs vides ne se dessinent pas et ne s'affichent pas dans "la Fenêtre des données", toutes les valeurs dans les tampons d'indicateur doivent être installés de manière explicite. L'initialisation des tampons par la valeur vide n'est pas produite.

//---établissons la valeur vide
PlotIndexSetDouble(l'index_de la construction_DRAW_ARROW,PLOT_EMPTY_VALUE,0);

Le nombre de tampons nécessaires pour la construction DRAW_ARROW – 1.

L'exemple de l'indicateur dessinant les flèches sur chaque barre, qui a le prix de la clôture Close plus grand que le prix de la clôture de la barre précédente La couleur, l'épaisseur et le code du symbole detoutesles flèches se changent chaques N ticks par hasard.

L'exemple du style DRAW_ARROW

Dans l'exemple les propriétés la couleur et la taille pour la construction graphique plot1 avec le style DRAW_ARROW sont spécifiés primordialement à l'aide de la directive du compilateur #property, et puis dans la fonction OnCalculate()les propriétés sont spécifiées par hasard. Le paramètre N est sorti dans les paramètres extérieurs de l'indicateur pour la possibilité de l'installation manuelle (l'onglet "Paramètres" dans la fenêtre des propriétés de l'indicateur).

//+------------------------------------------------------------------+
//|                                                   DRAW_ARROW.mq5 |
//|                         Copyright 2000-2024, MetaQuotes Ltd. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2000-2024, MetaQuotes Ltd."
#property link      "https://www.mql5.com"
#property version   "1.00"

#property description "L'indicateur pour la démonstration DRAW_ARROW"
#property description "Dessine les flèches, spécifiées par les symboles Unicode, sur le tableau"
#property description "La couleur, la taille, le décalage et le code du symbole de la flèche se changent par hasard"
#property description "dans chaques N ticks"
#property description "Le paramètre code spécifie la valeur de base: le code = 159 (cercle)"

#property indicator_chart_window
#property indicator_buffers 1
#property indicator_plots   1
//--- plot Arrows
#property indicator_label1  "Arrows"
#property indicator_type1   DRAW_ARROW
#property indicator_color1  clrGreen
#property indicator_width1  1
//--- les paramètres input
input int      N=5;         // le nombre de ticks pour le changement
input ushort   code=159;    // le code du symbole pour le dessin dans DRAW_ARROW
//--- le tampon d'indicateur pour la construction
double         ArrowsBuffer[];
//--- le tableau pour le stockage des couleurs
color colors[]={clrRed,clrBlue,clrGreen};
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int OnInit()
  {
//--- indicator buffers mapping
   SetIndexBuffer(0,ArrowsBuffer,INDICATOR_DATA);
//--- spécifions le code du symbole pour le dessin dans PLOT_ARROW
   PlotIndexSetInteger(0,PLOT_ARROW,code);
//--- spécifions le décalage des flèches selon le vertical en pixels
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,5);
//--- définissons 0 comme une valeur vide
   PlotIndexSetDouble(0,PLOT_EMPTY_VALUE,0);
//---
   return(INIT_SUCCEEDED);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int OnCalculate(const int rates_total,
                const int prev_calculated,
                const datetime &time[],
                const double &open[],
                const double &high[],
                const double &low[],
                const double &close[],
                const long &tick_volume[],
                const long &volume[],
                const int &spread[])
  {
   static int ticks=0;
//--- calculons les ticks pour le changement de la couleur, de la taille, de la confusion et du code de la flèche
   ticks++;
//--- si le nombre critique des ticks est accumulé
   if(ticks>=N)
     {
      //--- changeons les propriétés de la ligne
      ChangeLineAppearance();
      //---oblitérons le compteur des ticks au zéro
      ticks=0;
     }

//--- le bloc du calcul des valeurs de l'indicateur
   int start=1;
   if(prev_calculated>0) start=prev_calculated-1;
//--- la boucle du calcul
   for(int i=1;i<rates_total;i++)
     {
      //--- si le prix courant Close est plus grand que le précédent, mettons la flèche
      if(close[i]>close[i-1])
         ArrowsBuffer[i]=close[i];
      //--- dans le cas contraire spécifions la valeur nulle
      else
         ArrowsBuffer[i]=0;
     }
//--- return value of prev_calculated for next call
   return(rates_total);
  }
//+------------------------------------------------------------------+
//| modifie l'apparence des symboles dans l'indicateur                        |
//+------------------------------------------------------------------+
void ChangeLineAppearance()
  {
//--- la ligne pour la formation de l'information sur les propriétés de l'indicateur
   string comm="";
//--- le bloc du changement de la couleur de la flèche
   int number=MathRand(); // recevrons le nombre accidentel
//--- le diviseur du nombre est égal au montant du tableau colors[]
   int size=ArraySize(colors);
//--- recevrons l'index pour le choix de la nouvelle couleur comme le reste de la division entière
   int color_index=number%size;
//--- définissons la couleur comme la propriété PLOT_LINE_COLOR
   PlotIndexSetInteger(0,PLOT_LINE_COLOR,colors[color_index]);
//--- inscrirons la couleur de la ligne
   comm=comm+"\r\n"+(string)colors[color_index];

//--- le bloc du changement de la taille des flèches
   number=MathRand();
//--- recevrons l'épaisseur comme le reste de la division entière
   int width=number%5;   // on spécifie la taille de 0 jusqu'à 4
//--- définissons la couleur comme la propriété PLOT_LINE_WIDTH
   PlotIndexSetInteger(0,PLOT_LINE_WIDTH,width);
//--- inscrirons la taille des flèches
   comm=comm+"\r\nWidth="+IntegerToString(width);

//--- le bloc du changement du code de la flèche (PLOT_ARROW)
   number=MathRand();
//---recevrons le reste de la division entière pour le calcul du nouveau code de la flèche (de 0 jusqu'à 19)
   int code_add=number%20;
//---définissons un nouveau code du symbole comme la somme code+code_add
   PlotIndexSetInteger(0,PLOT_ARROW,code+code_add);
//--- inscrirons le code du symbole PLOT_ARROW
   comm="\r\n"+"PLOT_ARROW="+IntegerToString(code+code_add)+comm;

//--- le bloc du changement du décalage des flèches selon la verticale en pixels
   number=MathRand();
//--- recevrons le décalage comme le reste de la division entière
   int shift=20-number%41;
//--- définissons un nouveau décalage de-20 jusqu'à 20
   PlotIndexSetInteger(0,PLOT_ARROW_SHIFT,shift);
//--- inscrirons le décalage PLOT_ARROW_SHIFT
   comm="\r\n"+"PLOT_ARROW_SHIFT="+IntegerToString(shift)+comm;

//--- déduisons l'information sur le graphique par le commentaire
   Comment(comm);
  }

DRAW_HISTOGRAM2

DRAW_ZIGZAG