DocumentationSections
Référence MQL5Fonctions de ConversionEnumToString 

EnumToString

La transformation de la valeur de l'énumération de n'importe quel type à la représentation de texte.

string  EnumToString(
   any_enum  value      // La valeur de l'énumération de tout type 
   );

Paramètres

value

[in]  La valeur de l'énumération de tout type.

La valeur rendue

Une chaîne contenant la représentation de texte de la valeur. Pour recevoir l'information sur l'erreur, il faut appeler la fonction GetLastError().

Note

La fonction peut définir dans la variable _LastError les valeurs suivantes des erreurs:

  • ERR_INTERNAL_ERROR — l'erreur de l'environnement de l'exécution
  • ERR_NOT_ENOUGH_MEMORY - pas assez de mémoire pour terminer l'opération
  • ERR_INVALID_PARAMETER - Il est impossible de permettre le nom de la valeur de l'énumération

 

Exemple:

enum interval  // l'énumération des constantes nommées
  {
   month=1,     // l'intervalle dans un mois
   two_months,  // deux mois
   quarter,     // trois mois - le quartier
   halfyear=6,  // le semestre
   year=12,     // un an - 12 mois
  };
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart()
  {
//--- établissons  l'intervalle temporaire qui est égal au mois
   interval period=month;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- établissons  l'intervalle temporaire qui est égal au quartier (trois mois))
   period=quarter;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- établissons  l'intervalle temporaire qui est égal à un an (12 mois))
   period=year;
   Print(EnumToString(period)+"="+IntegerToString(period));
 
//--- vérifions comment le type de l'ordre est déduit
   ENUM_ORDER_TYPE type=ORDER_TYPE_BUY;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
//--- vérifions comment une valeur incorrecte est déduite
   type=WRONG_VALUE;
   Print(EnumToString(type)+"="+IntegerToString(type));
 
// Le résultat de l'exécution:
// month=1
// quarter=3
// year=12
// ORDER_TYPE_BUY=0
// ENUM_ORDER_TYPE::-1=-1
  }

Voir aussi

Les énumérations, Input les variables