//--- description
#property description "Le script crée des lignes de cycle sur le graphique."
#property description "Les coordonnées des points d'ancrage sont défini en pourcentage"
#property description "pourcentage de la taille de la fenêtre du graphique"
//--- affichage de la fenêtre des paramètres d'entrée lors du lancement du script
#property script_show_inputs
//--- paramètres d'entrée du script
input string InpName="Cycles"; // nom de l'objet
input int InpDate1=10; // Date du premier point, %
input int InpPrice1=45; // Prix du premier point, %
input int InpDate2=20; // Date du second point, %
input int InpPrice2=55; // Prix du second point, %
input color InpColor=clrRed; // Couleur des lignes de cycle
input ENUM_LINE_STYLE InpStyle=STYLE_DOT; // Style des lignes de cycle
input int InpWidth=1; // Largeur des lignes de cycle
input bool InpBack=false; // Objet en arrière plan
input bool InpSelection=true; // mise en surbrillance pour le déplacement
input bool InpHidden=true; // caché dans la liste des objets
input long InpZOrder=0; // priorité pour le clic de souris
//+----------------------------------------------------------------------------------------------------+
//| Crée les lignes de cycle |
//+----------------------------------------------------------------------------------------------------+
bool CyclesCreate(const long chart_ID=0, // identifiant du graphique
const string name="Cycles", // nom de l'objet
const int sub_window=0, // indice de sous-fenêtre
datetime time1=0, // heure du premier point
double price1=0, // prix du premier point
datetime time2=0, // heure du deuxième point
double price2=0, // prix du deuxième point
const color clr=clrRed, // couleur des lignes de cycle
const ENUM_LINE_STYLE style=STYLE_SOLID, // style des lignes de cycle
const int width=1, // largeur des lignes de cycle
const bool back=false, // en arrière-plan
const bool selection=true, // mise en surbrillance pour le déplacement
const bool hidden=true, // caché dans la liste des objets
const long z_order=0) // priorité du clic de souris
{
//--- définit les coordonnées du point d'ancrage si elles ne sont pas définies
ChangeCyclesEmptyPoints(time1,price1,time2,price2);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- crée les lignes de cycle aux coordonnées données
if(!ObjectCreate(chart_ID,name,OBJ_CYCLES,sub_window,time1,price1,time2,price2))
{
Print(__FUNCTION__,
" : échec de création des lignes de cycle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- définit la couleur des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clr);
//--- définit le style d'affichage des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_STYLE,style);
//--- définit la largeur des lignes
ObjectSetInteger(chart_ID,name,OBJPROP_WIDTH,width);
//--- affiche en premier plan (false) ou en arrière-plan (true)
ObjectSetInteger(chart_ID,name,OBJPROP_BACK,back);
//--- active (true) ou désactive (false) le mode de déplacement des lignes à la souris
//--- lors de la création d'un objet graphique utilisant la fonction ObjectCreate, l'objet ne peut pas être
//--- mis en surbrillance et déplacé par défaut. Dans cette méthode, le paramètre de sélection
//--- est vrai par défaut, permettant de mettre en surbrillance et de déplacer l'objet
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTABLE,selection);
ObjectSetInteger(chart_ID,name,OBJPROP_SELECTED,selection);
//--- masque (true) ou affiche (false) le nom de l'objet graphique dans la liste des objets
ObjectSetInteger(chart_ID,name,OBJPROP_HIDDEN,hidden);
//--- définit la priorité pour recevoir l'événement d'un clic de souris dans le graphique
ObjectSetInteger(chart_ID,name,OBJPROP_ZORDER,z_order);
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Déplace le point d'ancrage |
//+----------------------------------------------------------------------------------------------------+
bool CyclesPointChange(const long chart_ID=0, // identifiant du graphique
const string name="Cycles", // nom de l'objet
const int point_index=0, // indice du point d'ancrage
datetime time=0, // coordonnées du point d'ancrage temporel
double price=0) // coordonnées du point d'ancrage prix
{
//--- si la position du point n'est pas définie, le déplace vers la barre courante du prix Bid
if(!time)
time=TimeCurrent();
if(!price)
price=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- déplace le point d'ancrage
if(!ObjectMove(chart_ID,name,point_index,time,price))
{
Print(__FUNCTION__,
" : impossible de déplacer le point d'ancrage ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Supprime les lignes de cycle |
//+----------------------------------------------------------------------------------------------------+
bool CyclesDelete(const long chart_ID=0, // identifiant du graphique
const string name="Cycles") // nom de l'objet
{
//--- réinitialise la valeur d'erreur
ResetLastError();
//--- supprime les lignes de cycle
if(!ObjectDelete(chart_ID,name))
{
Print(__FUNCTION__,
" : échec de suppression des lignes de cycle ! Code d'erreur = ",GetLastError());
return(false);
}
//--- exécution réussie
return(true);
}
//+----------------------------------------------------------------------------------------------------+
//| Vérifie les valeurs des points d'ancrage des lignes de cycle et définit la valeur |
//| par défaut des points vides |
//+----------------------------------------------------------------------------------------------------+
void ChangeCyclesEmptyPoints(datetime &time1,double &price1,
datetime &time2,double &price2)
{
//--- si l'heure du premier point n'est pas définie, elle sera définie sur la barre courante
if(!time1)
time1=TimeCurrent();
//--- si le prix du premier point n'est pas défini, il aura la valeur Bid
if(!price1)
price1=SymbolInfoDouble(Symbol(),SYMBOL_BID);
//--- si l'heure du second point n'est pas réglée, elle se trouve à 9 barres de la seconde
if(!time2)
{
//--- tableau pour recevoir l'heure d'ouverture des 10 dernières barres
datetime temp[10];
CopyTime(Symbol(),Period(),time1,10,temp);
//--- Positionne le deuxième point à 9 barres à gauche du premier
time2=temp[0];
}
//--- si le prix du deuxième point n'est pas défini, il est égal à celui du premier point
if(!price2)
price2=price1;
}
//+----------------------------------------------------------------------------------------------------+
//| Fonction de démarrage du script |
//+----------------------------------------------------------------------------------------------------+
void OnStart()
{
//--- vérifie l'exactitude des paramètres d'entrée
if(InpDate1<0 || InpDate1>100 || InpPrice1<0 || InpPrice1>100 ||
InpDate2<0 || InpDate2>100 || InpPrice2<0 || InpPrice2>100)
{
Print("Erreur ! Valeurs incorrectes des paramètres d'entrée !");
return;
}
//--- nombre de barres visibles dans la fenêtre du graphique
int bars=(int)ChartGetInteger(0,CHART_VISIBLE_BARS);
//--- taille du tableau des prix
int accuracy=1000;
//--- tableaux pour stocker les valeurs de date et de prix à utiliser
//--- pour définir et changer les coordonnées des points d'ancrage des lignes de cycle
datetime date[];
double price[];
//--- allocation mémoire
ArrayResize(date,bars);
ArrayResize(price,accuracy);
//--- remplit le tableau de dates
ResetLastError();
if(CopyTime(Symbol(),Period(),0,bars,date)==-1)
{
Print("N'a pas réussi à copier les valeurs de l'heure ! Code d'erreur = ",GetLastError());
return;
}
//--- remplit le tableau des prix
//--- trouve les valeurs les plus élevées et les plus faibles du graphique
double max_price=ChartGetDouble(0,CHART_PRICE_MAX);
double min_price=ChartGetDouble(0,CHART_PRICE_MIN);
//--- définit un changement de prix et remplit le tableau
double step=(max_price-min_price)/accuracy;
for(int i=0;i<accuracy;i++)
price[i]=min_price+i*step;
//--- définit les points pour dessiner les lignes de cycle
int d1=InpDate1*(bars-1)/100;
int d2=InpDate2*(bars-1)/100;
int p1=InpPrice1*(accuracy-1)/100;
int p2=InpPrice2*(accuracy-1)/100;
//--- crée une ligne de tendance
if(!CyclesCreate(0,InpName,0,date[d1],price[p1],date[d2],price[p2],InpColor,
InpStyle,InpWidth,InpBack,InpSelection,InpHidden,InpZOrder))
{
return;
}
//--- redéssine le graphique et attend 1 seconde
ChartRedraw();
Sleep(1000);
//--- déplace maintenant les points d'ancrage
//--- compteur de boucle
int h_steps=bars/5;
//--- déplace le second point d'ancrage
for(int i=0;i<h_steps;i++)
{
//--- utilise la valeur suivante
if(d2<bars-1)
d2+=1;
//--- déplace le point
if(!CyclesPointChange(0,InpName,1,date[d2],price[p2]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
// délai de 0,05 secondes
Sleep(50);
}
//--- délai de 1 seconde
Sleep(1000);
//--- compteur de boucle
h_steps=bars/4;
//--- déplace le premier point d'ancrage
for(int i=0;i<h_steps;i++)
{
//--- utilise la valeur suivante
if(d1<bars-1)
d1+=1;
//--- déplace le point
if(!CyclesPointChange(0,InpName,0,date[d1],price[p1]))
return;
//--- vérifie si l'exécution du script a été stoppée
if(IsStopped())
return;
//--- redessine le graphique
ChartRedraw();
// délai de 0,05 secondes
Sleep(50);
}
//--- délai de 1 seconde
Sleep(1000);
//--- supprime l'objet du graphique
CyclesDelete(0,InpName);
ChartRedraw();
//--- délai de 1 seconde
Sleep(1000);
//---
}
|
