Opposite trade - Experte für den MetaTrader 5

Eröffnen der neue Position entgegengesetzt zur vorherigen, mit gleichem Volumen. Es funktioniert für jedes Symbol und jeder 'magic number'.

Wir haben beispielsweise eine offene Position AUDUSD, BUY, 0,01. Sobald diese Position geschlossen wird (z. B. manuell), wird der Expert Advisor sofort mit AUDUSD eine neue, entgegengesetzte Position eröffnen, dies ist nun eine VERKAUF-Position.

Der gesamte Code ist in der Funktion OnTradeTransaction enthalten:

//+------------------------------------------------------------------+
//| TradeTransaction Funktion                                        |
//+------------------------------------------------------------------+
void OnTradeTransaction(const MqlTradeTransaction &trans,
                        const MqlTradeRequest &request,
                        const MqlTradeResult &result)
  {
//--- Abfrage des Positionstyp als Wert der Enumeration 
   ENUM_TRADE_TRANSACTION_TYPE type=trans.type;
//--- Falls die Transaktion das Ergebnis von Additionen geschlossener Positionen ist
   if(type==TRADE_TRANSACTION_DEAL_ADD)
     {
      long     deal_type         =-1;
      long     deal_entry        =-1;
      double   deal_volume       =0.0;
      string   deal_symbol       ="";
      if(HistoryDealSelect(trans.deal))
        {
         deal_type         =HistoryDealGetInteger(trans.deal,DEAL_TYPE);
         deal_entry        =HistoryDealGetInteger(trans.deal,DEAL_ENTRY);
         deal_volume       =HistoryDealGetDouble(trans.deal,DEAL_VOLUME);
         deal_symbol       =HistoryDealGetString(trans.deal,DEAL_SYMBOL);
        }
      else
         return;
      if(deal_entry==DEAL_ENTRY_OUT)
        {
         switch((int)deal_type)
           {
            case  DEAL_TYPE_BUY:
               m_trade.Buy(deal_volume,deal_symbol);
               break;
            case  DEAL_TYPE_SELL:
               m_trade.Sell(deal_volume,deal_symbol);
               break;
            default:
               break;
           }
        }
     }
  }

Hier warten wir auf das Schließen der Position (DEAL_ENTRY_OUT). Sobald dieser 'deal' erscheint, überprüfen wir die Position des 'deals' (wenn wir einen KAUFEN schließen, wird dies ein Verkauf werden und umgekehrt) und wir eröffnen eine neue Position.