KimIV的有用功能

Igor Kim 2008.04.16 13:43 #121

olyakish:

伊戈尔，我在"处理INI文件的函数库 " 中问过你一个问题，但没有答复:(

谢谢...回答了...

Igor Kim 2008.04.16 14:08 #122

ClosePosBySelect()函数。

关闭一个预选的位置。这个函数是相当辅助的，因为它是由其他几个函数调用的，这些函数有助于通过一些条件来选择关闭的位置。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 19.02.2008                                                      |
//|  Описание: Закрытие одной предварительно выбранной позиции                 |
//+----------------------------------------------------------------------------+
void ClosePosBySelect() {
  bool   fc;
  color  clClose;
  double ll, pa, pb, pp;
  int    err, it;

  if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      pa=MarketInfo(OrderSymbol(), MODE_ASK);
      pb=MarketInfo(OrderSymbol(), MODE_BID);
      if (OrderType()==OP_BUY) {
        pp=pb; clClose=clCloseBuy;
      } else {
        pp=pa; clClose=clCloseSell;
      }
      ll=OrderLots();
      fc=OrderClose(OrderTicket(), ll, pp, Slippage, clClose);
      if (fc) {
        if (UseSound) PlaySound(NameFileSound); break;
      } else {
        err=GetLastError();
        if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
        Print("Error(",err,") Close ",GetNameOP(OrderType())," ",
              ErrorDescription(err),", try ",it);
        Print(OrderTicket(),"  Ask=",pa,"  Bid=",pb,"  pp=",pp);
        Print("sy=",OrderSymbol(),"  ll=",ll,"  sl=",OrderStopLoss(),
              "  tp=",OrderTakeProfit(),"  mn=",OrderMagicNumber());
        Sleep(1000*5);
      }
    }
  } else Print("Некорректная торговая операция. Close ",GetNameOP(OrderType()));
}

Alexey Klenov 2008.04.17 11:28 #123

KimIV:

谢谢你...已回答...

另一个问题（或者说是声明）也在那里 :)

alexvor 2008.04.17 13:21 #124

KimIV:

ClosePosBySelect()函数。

关闭一个预选的位置。这个函数是相当辅助性的，因为它是由其他几个函数调用的，这些函数有助于根据一些条件选择要关闭的位置。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 19.02.2008                                                      |
//|  Описание: Закрытие одной предварительно выбранной позиции                 |
//+----------------------------------------------------------------------------+
void ClosePosBySelect() {
  bool   fc;
  color  clClose;
  double ll, pa, pb, pp;
  int    err, it;

  if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      pa=MarketInfo(OrderSymbol(), MODE_ASK);
      pb=MarketInfo(OrderSymbol(), MODE_BID);
      if (OrderType()==OP_BUY) {
        pp=pb; clClose=clCloseBuy;
      } else {
        pp=pa; clClose=clCloseSell;
      }
      ll=OrderLots();
      fc=OrderClose(OrderTicket(), ll, pp, Slippage, clClose);
      if (fc) {
        if (UseSound) PlaySound(NameFileSound); break;
      } else {
        err=GetLastError();
        if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
        Print("Error(",err,") Close ",GetNameOP(OrderType())," ",
              ErrorDescription(err),", try ",it);
        Print(OrderTicket(),"  Ask=",pa,"  Bid=",pb,"  pp=",pp);
        Print("sy=",OrderSymbol(),"  ll=",ll,"  sl=",OrderStopLoss(),
              "  tp=",OrderTakeProfit(),"  mn=",OrderMagicNumber());
        Sleep(1000*5);
      }
    }
  } else Print("Некорректная торговая операция. Close ",GetNameOP(OrderType()));
}

你好!

请原谅我!

1) 我不明白这句话的意思for (it=1; it<=NumberOfTry; it++)

这是个什么样的循环？

2) 我也不理解条件if (!testing() ......) break。

3）最后，这是什么功能？ ErrorDescription(err)," 。

如果你不介意的话，请解释一下。

Igor Kim 2008.04.18 01:23 #125

1.这是一个交易尝试的循环。如果交易服务器返回错误，该函数将进行NumberOfTry 尝试，最终平仓。我通常设置NumberOfTry=5。

2.这个条件实现了当在线工作的专家顾问被停止时，能够正确退出尝试的周期。如果没有这个条件，为了调用，例如，EA的属性，我们不得不等待，直到EA使用所有的交易尝试，或者从图表中删除EA。

3.在文件.\experts\libraries\stdlib.mq4中查找。

[删除] 2008.04.18 07:24 #126

我想问一下，如何使EA在无限循环中工作，同时又能访问其参数设置？

我在开始时是这样写的

while (true)
{
  // проверка на останов и прочее
      if (IsStopped()) 
        return(-1);
  while (isRefresh == false)
       isRefresh = RefreshRates();
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

但在这种情况下，专家顾问挂起，除了从图表中删除外，我不能对它做任何事情。

Igor Kim 2008.04.18 13:07 #127

瓦莱拉，让它变成这样。

while (IsExpertEnabled() && !IsStopped())
{
  while (!RefreshRates()) Sleep(500);
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

Igor Kim 2008.04.20 06:18 #128

ClosePosBySizeProfitInCurrency()函数。

这个功能只关闭那些存款货币的利润超过某个特定值的头寸。你可以用函数参数指定哪些位置必须关闭。

sy- 仪器的名称。如果你设置了这个参数，函数将只检查指定仪器的位置。NULL 表示当前的仪器，而""（默认）表示任何仪器。
op- 贸易操作，职位类型。有效值：OP_BUY、OP_SELL 或-1。默认值-1 意味着任何位置。
mn- 位置标识符（MagicNumber）。默认值-1 - 表示任何MagicNumber。
pr- 存款货币的利润水平。默认值--0。

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Закрытие тех позиций, у которых профит в валюте депозита       |
//|             превысил некоторое значение                                    |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//|    pr - профит                                                             |
//+----------------------------------------------------------------------------+
void ClosePosBySizeProfitInCurrency(string sy="", int op=-1, int mn=-1, double pr=0) {
  int i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=k-1; i>=0; i--) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (OrderProfit()+OrderSwap()>pr) ClosePosBySelect();
          }
        }
      }
    }
  }
}

只有 KimIV 的有用功能。 [存档！]任何菜鸟问题，为了不使论坛变得混乱。专业人士，不要路过。没有你，哪里都不能去 - 4. 并让我们把它做成一个 "卡通"（多货币）。

[删除] 2008.04.22 05:54 #129

KimIV:

瓦莱拉，让它变成这样。

while (IsExpertEnabled() && !IsStopped())
{
  while (!RefreshRates()) Sleep(500);
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

唉，這也是在廣播 ekspert，在您把它從圖表中刪除之前，不能訪問其參數。

Igor Kim 2008.04.22 06:55 #130

scorpionk:

唉，这也是对EA的广播，在你把它从图表中删除之前，不能访问它的参数。

然而，它确实给了你一个选项，即按下工具栏上的 "EA "按钮来停止该EA。

KimIV的有用功能 - 页 13

ClosePosBySelect()函数。

ClosePosBySelect()函数。

ClosePosBySizeProfitInCurrency()函数。