基于艾略特波浪理论的交易策略

Forex Trader 2006.03.11 16:50 #61

Forex Trader 2006.03.11 17:54 #62

亚历克斯-尼罗巴，为什么只有我一个人被如此对待？

Forex Trader 2006.03.11 17:59 #63

<br / translate="no"> Alex Niroba 11.03.06 17:50
...
当然，画面还远远不够完整，但通过一些人物，你可以
已经得出了某些结论...
...

尼罗巴，你是想玩娃娃吗？或狼和羊 :)?

Forex Trader 2006.03.11 23:22 #64

正如solandr 相当准确地指出的那样。

这个主题已经包含了3页无用的垃圾，没有任何有用的信息!

而在我看来，已经没有什么可期待的了。因为，至少对发起这个话题的人来说，完全没有什么可说的。他今天确实发了一个新的帖子，但不幸的是，版主认为应该把它完全删除。太糟糕了。这个尼罗巴在 第三天写信给我

你认为你很聪明，但你仍然需要学习一些礼仪。

我想向他学习，但我没有机会。显然，这位精通礼仪的大专家，不仅有时接不上话，而且一旦接上话，也不怎么检点。

嗯，他怎么了。这个问题是不同的。
如果这个主题的发起人，除了文字之外不能提供任何东西，那么我们在这里做什么呢？
为什么这个主题还活着？

Forex Trader 2006.03.11 23:44 #65

在交易时段之间吱吱喳喳很有意思 :)

Forex Trader 2006.03.12 13:13 #66

<br/ translate="no"> Vladislav，这个主题已经包含了3页无用的垃圾，没有任何有用的信息!但在我看来，如果你能更详细地描述你的策略，就能拯救这个话题。

我在此基础上进行预测的指标在蜘蛛网上可以免费获得）。我也会把它放在这里--它是穆雷水平的一个指标。现在谈一下数学：这些水平的主要问题是，事后指出它们的重要性非常容易，但先验地定义它们却非易事。在本土网站上有一堆改善情况的方法，但在我看来，这些方法在数学上并不靠谱（还有江恩和艾略特的理论--即定性描述很高，但当涉及到定量估计时--则是不确定的）。在一个特定的情况下为解决一个问题（关于一个声明和方法的决定曾经试图拿出对一个蜘蛛在一个分支约一厘米，但他们没有考虑有趣的有:)- 讨论共同的主题比制定定量评价的方法更容易 :)- 然而那是过去的事了）是的，关于问题的陈述、假设以及合适的解决方法的选择和评估是一个单独的话题。所做的最重要的事情是--问题的设置方式意味着非随机预测的可能性，以及对获得的结果进行一些概率性的评估。现在我省略了关于市场效率理论的问题--我想指出的是，它只是一种理论，不比其他非自相矛盾的方法多，也不比他们好，更不比他们差。例如，R/S统计（也被称为Hurst标准）对欧元价格系列给出了超过0.5（大约0.64 - 这是在你采取所有系列的情况下），这又意味着非随机预测的可能性和趋势预测模型的优势。例如，我就采取了不同的方法--有些时候，可靠的预测是可能的（Hurst系数与0.5有很大差别），有些时候是不可能的（没有什么差别）。有些时候，趋势方法是有利的（K因子约为1），反趋势方法是有利的（K因子约为0）。结果如下--我们不仅获得了衍生出枢轴点的默里水平，而且还获得了它们在这个时间点的统计意义。这就是同一个级别在不同的时间以不同的面貌出现（多么合适啊:）。也就是说，在某些时候，这个水平可能作为一个突破位，在某些情况下，它根本不被考虑，有时它是一个突破位，尽管根据策略，当这个水平被定义为一个突破位时，交易者应该持有一个头寸，这个头寸通常是盈利的，唯一的事情是将止损移到一个适当的水平。更确切地说，作为计算的结果，交易者将获得一些由默里水平和渠道边界限制的转弯区域（这是建立

置信区间预测的时候）--置信区间水平本身切断了预测履行的概率水平，而渠道边界和默里水平的交汇点提供了时间的估值。你可以在图表上清楚地看到它。这是在一般情况下，可以说是 "在手指上"。更具体地说，我用线性回归通道预测趋势运动+计算给定通道的赫斯特标准来补充默里水平的计算（绘制通道的抽样标准也是不简单的）。选择的理由：我在上面写到了Hurst准则，以及关于通道：你可以在任何时刻建立相当多的线性回归通道，但只有线性回归通道会有最小的误差。对于预测来说，最好是在给定的时间采取最佳的近似值。这就是全部--这就够了，可以开始了；）。这将节省非常可观的用于研究的时间。如果对编程感到 "厌烦"--几乎所有这些都可以通过MT4标准手段获得--除了Murray水平和Hurst准则，但水平是免费提供的，而没有Hurst，它们的效果也不会差很多。我还应该指出，在以前的版本中，有一个小错误导致了错误的历史绘制。所以你最好在这里得到它：

//+------------------------------------------------------------------+
//|                                            Murrey_Math_MT_VG.mq4 |
//|                       Copyright © 2004, Vladislav Goshkov (VG).  |
//|                                           4vg@mail.ru            |
//+------------------------------------------------------------------+
#property copyright "Vladislav Goshkov (VG)."
#property link      "4vg@mail.ru"

#property indicator_chart_window

// ============================================================================================
// * Линии 8/8 и 0/8 (Окончательное сопротивление).
// * Эти линии самые сильные и оказывают сильнейшие сопротивления и поддержку.
// ============================================================================================
//* Линия 7/8  (Слабая, место для остановки и разворота). Weak, Stall and Reverse
//* Эта линия слаба. Если цена зашла слишком далеко и слишком быстро и если она остановилась около этой линии, 
//* значит она развернется быстро вниз. Если цена не остановилась около этой линии, она продолжит движение вверх к 8/8.
// ============================================================================================
//* Линия 1/8  (Слабая, место для остановки и разворота). Weak, Stall and Reverse
//* Эта линия слаба. Если цена зашла слишком далеко и слишком быстро и если она остановилась около этой линии, 
//* значит она развернется быстро вверх. Если цена не остановилась около этой линии, она продолжит движение вниз к 0/8.
// ============================================================================================
//* Линии 6/8 и 2/8 (Вращение, разворот). Pivot, Reverse
//* Эти две линии уступают в своей силе только 4/8 в своей способности полностью развернуть ценовое движение.
// ============================================================================================
//* Линия 5/8 (Верх торгового диапазона). Top of Trading Range
//* Цены всех рынков тратят 40% времени, на движение между 5/8 и 3/8 линиями. 
//* Если цена двигается около линии 5/8 и остается около нее в течении 10-12 дней, рынок сказал что следует 
//* продавать в этой «премиальной зоне», что и делают некоторые люди, но если цена сохраняет тенденцию оставаться 
//* выше 5/8, то она и останется выше нее. Если, однако, цена падает ниже 5/8, то она скорее всего продолжит 
//* падать далее до следующего уровня сопротивления.
// ============================================================================================
//* Линия 3/8 (Дно торгового диапазона). Bottom of Trading Range
//* Если цены ниже этой лини и двигаются вверх, то цене будет сложно пробить этот уровень. 
//* Если пробивают вверх эту линию и остаются выше нее в течении 10-12 дней, значит цены останутся выше этой линии 
//* и потратят 40% времени двигаясь между этой линией и 5/8 линией.
// ============================================================================================
//* Линия 4/8 (Главная линия сопротивления/поддержки). Major Support/Resistance
//* Эта линия обеспечивает наибольшее сопротивление/поддержку. Этот уровень является лучшим для новой покупки или продажи. 
//* Если цена находится выше 4/8, то это сильный уровень поддержки. Если цена находится ниже 4/8, то это прекрасный уровень 
//* сопротивления.
// ============================================================================================
extern int P = 64;
extern int MMPeriod = 1440;
extern int StepBack = 0;

extern color  mml_clr_m_2_8 = White;       // [-2]/8
extern color  mml_clr_m_1_8 = White;       // [-1]/8
extern color  mml_clr_0_8   = Aqua;        //  [0]/8
extern color  mml_clr_1_8   = Yellow;      //  [1]/8
extern color  mml_clr_2_8   = Red;         //  [2]/8
extern color  mml_clr_3_8   = Green;       //  [3]/8
extern color  mml_clr_4_8   = Blue;        //  [4]/8
extern color  mml_clr_5_8   = Green;       //  [5]/8
extern color  mml_clr_6_8   = Red;         //  [6]/8
extern color  mml_clr_7_8   = Yellow;      //  [7]/8
extern color  mml_clr_8_8   = Aqua;        //  [8]/8
extern color  mml_clr_p_1_8 = White;       // [+1]/8
extern color  mml_clr_p_2_8 = White;       // [+2]/8

extern int    mml_wdth_m_2_8 = 2;        // [-2]/8
extern int    mml_wdth_m_1_8 = 1;       // [-1]/8
extern int    mml_wdth_0_8   = 1;        //  [0]/8
extern int    mml_wdth_1_8   = 1;      //  [1]/8
extern int    mml_wdth_2_8   = 1;         //  [2]/8
extern int    mml_wdth_3_8   = 1;       //  [3]/8
extern int    mml_wdth_4_8   = 1;        //  [4]/8
extern int    mml_wdth_5_8   = 1;       //  [5]/8
extern int    mml_wdth_6_8   = 1;         //  [6]/8
extern int    mml_wdth_7_8   = 1;      //  [7]/8
extern int    mml_wdth_8_8   = 1;        //  [8]/8
extern int    mml_wdth_p_1_8 = 1;       // [+1]/8
extern int    mml_wdth_p_2_8 = 2;       // [+2]/8

extern color  MarkColor   = Blue;
extern int    MarkNumber  = 217;


double  dmml = 0,
        dvtl = 0,
        sum  = 0,
        v1 = 0,
        v2 = 0,
        mn = 0,
        mx = 0,
        x1 = 0,
        x2 = 0,
        x3 = 0,
        x4 = 0,
        x5 = 0,
        x6 = 0,
        y1 = 0,
        y2 = 0,
        y3 = 0,
        y4 = 0,
        y5 = 0,
        y6 = 0,
        octave = 0,
        fractal = 0,
        range   = 0,
        finalH  = 0,
        finalL  = 0,
        mml[13];

string  ln_txt[13],        
        buff_str = "";
        
int     
        bn_v1   = 0,
        bn_v2   = 0,
        OctLinesCnt = 13,
        mml_thk = 8,
        mml_clr[13],
        mml_wdth[13],
        mml_shft = 35,
        nTime = 0,
        CurPeriod = 0,
        nDigits = 0,
        i = 0;
int NewPeriod=0;
//+------------------------------------------------------------------+
//| Custom indicator initialization function                         |
//+------------------------------------------------------------------+
int init() {
//---- indicators
   if(MMPeriod>0)
      NewPeriod   = P*MathCeil(MMPeriod/Period());
   else NewPeriod = P;
   
   ln_txt[0]  = "[-2/8]P";// "extremely overshoot [-2/8]";// [-2/8]
   ln_txt[1]  = "[-1/8]P";// "overshoot [-1/8]";// [-1/8]
   ln_txt[2]  = "[0/8]P";// "Ultimate Support - extremely oversold [0/8]";// [0/8]
   ln_txt[3]  = "[1/8]P";// "Weak, Stall and Reverse - [1/8]";// [1/8]
   ln_txt[4]  = "[2/8]P";// "Pivot, Reverse - major [2/8]";// [2/8]
   ln_txt[5]  = "[3/8]P";// "Bottom of Trading Range - [3/8], if 10-12 bars then 40% Time. BUY Premium Zone";//[3/8]
   ln_txt[6]  = "[4/8]P";// "Major Support/Resistance Pivotal Point [4/8]- Best New BUY or SELL level";// [4/8]
   ln_txt[7]  = "[5/8]P";// "Top of Trading Range - [5/8], if 10-12 bars then 40% Time. SELL Premium Zone";//[5/8]
   ln_txt[8]  = "[6/8]P";// "Pivot, Reverse - major [6/8]";// [6/8]
   ln_txt[9]  = "[7/8]P";// "Weak, Stall and Reverse - [7/8]";// [7/8]
   ln_txt[10] = "[8/8]P";// "Ultimate Resistance - extremely overbought [8/8]";// [8/8]
   ln_txt[11] = "[+1/8]P";// "overshoot [+1/8]";// [+1/8]
   ln_txt[12] = "[+2/8]P";// "extremely overshoot [+2/8]";// [+2/8]

   //mml_shft = 3;
   mml_thk  = 3;

   // Начальная установка цветов уровней октав и толщины линий
   mml_clr[0]  = mml_clr_m_2_8;   mml_wdth[0] = mml_wdth_m_2_8; // [-2]/8
   mml_clr[1]  = mml_clr_m_1_8;   mml_wdth[1] = mml_wdth_m_1_8; // [-1]/8
   mml_clr[2]  = mml_clr_0_8;     mml_wdth[2] = mml_wdth_0_8;   //  [0]/8
   mml_clr[3]  = mml_clr_1_8;     mml_wdth[3] = mml_wdth_1_8;   //  [1]/8
   mml_clr[4]  = mml_clr_2_8;     mml_wdth[4] = mml_wdth_2_8;   //  [2]/8
   mml_clr[5]  = mml_clr_3_8;     mml_wdth[5] = mml_wdth_3_8;   //  [3]/8
   mml_clr[6]  = mml_clr_4_8;     mml_wdth[6] = mml_wdth_4_8;   //  [4]/8
   mml_clr[7]  = mml_clr_5_8;     mml_wdth[7] = mml_wdth_5_8;   //  [5]/8
   mml_clr[8]  = mml_clr_6_8;     mml_wdth[8] = mml_wdth_6_8;   //  [6]/8
   mml_clr[9]  = mml_clr_7_8;     mml_wdth[9] = mml_wdth_7_8;   //  [7]/8
   mml_clr[10] = mml_clr_8_8;     mml_wdth[10]= mml_wdth_8_8;   //  [8]/8
   mml_clr[11] = mml_clr_p_1_8;   mml_wdth[11]= mml_wdth_p_1_8; // [+1]/8
   mml_clr[12] = mml_clr_p_2_8;   mml_wdth[12]= mml_wdth_p_2_8; // [+2]/8
   
   
//----
   return(0);
  }

//+------------------------------------------------------------------+
//| Custor indicator deinitialization function                       |
//+------------------------------------------------------------------+
int deinit() {
//---- TODO: add your code here
Comment(" ");   
for(i=0;i<OctLinesCnt;i++) {
    buff_str = "mml"+i;
    ObjectDelete(buff_str);
    buff_str = "mml_txt"+i;
    ObjectDelete(buff_str);
    }
//----
   return(0);
  }
//+------------------------------------------------------------------+
//| Custom indicator iteration function                              |
//+------------------------------------------------------------------+
int start() {

//---- TODO: add your code here

if( (nTime != Time[0]) || (CurPeriod != Period()) ) {
   
  //price
   bn_v1 = Lowest(NULL,0,MODE_LOW,NewPeriod,StepBack);
   bn_v2 = Highest(NULL,0,MODE_HIGH,NewPeriod,StepBack);

   v1 = Low[bn_v1];
   v2 = High[bn_v2];

//determine fractal.....
   if( v2<=250000 && v2>25000 )
   fractal=100000;
   else
     if( v2<=25000 && v2>2500 )
     fractal=10000;
     else
       if( v2<=2500 && v2>250 )
       fractal=1000;
       else
         if( v2<=250 && v2>25 )
         fractal=100;
         else
           if( v2<=25 && v2>12.5 )
           fractal=12.5;
           else
             if( v2<=12.5 && v2>6.25)
             fractal=12.5;
             else
               if( v2<=6.25 && v2>3.125 )
               fractal=6.25;
               else
                 if( v2<=3.125 && v2>1.5625 )
                 fractal=3.125;
                 else
                   if( v2<=1.5625 && v2>0.390625 )
                   fractal=1.5625;
                   else
                     if( v2<=0.390625 && v2>0)
                     fractal=0.1953125;
      
   range=(v2-v1);
   sum=MathFloor(MathLog(fractal/range)/MathLog(2));
   octave=fractal*(MathPow(0.5,sum));
   mn=MathFloor(v1/octave)*octave;
   if( (mn+octave)>v2 )
   mx=mn+octave; 
   else
     mx=mn+(2*octave);


// calculating xx
//x2
    if( (v1>=(3*(mx-mn)/16+mn)) && (v2<=(9*(mx-mn)/16+mn)) )
    x2=mn+(mx-mn)/2; 
    else x2=0;
//x1
    if( (v1>=(mn-(mx-mn)/8))&& (v2<=(5*(mx-mn)/8+mn)) && (x2==0) )
    x1=mn+(mx-mn)/2; 
    else x1=0;

//x4
    if( (v1>=(mn+7*(mx-mn)/16))&& (v2<=(13*(mx-mn)/16+mn)) )
    x4=mn+3*(mx-mn)/4; 
    else x4=0;

//x5
    if( (v1>=(mn+3*(mx-mn)/8))&& (v2<=(9*(mx-mn)/8+mn))&& (x4==0) )
    x5=mx; 
    else  x5=0;

//x3
    if( (v1>=(mn+(mx-mn)/8))&& (v2<=(7*(mx-mn)/8+mn))&& (x1==0) && (x2==0) && (x4==0) && (x5==0) )
    x3=mn+3*(mx-mn)/4; 
    else x3=0;

//x6
    if( (x1+x2+x3+x4+x5) ==0 )
    x6=mx; 
    else x6=0;

     finalH = x1+x2+x3+x4+x5+x6;
// calculating yy
//y1
    if( x1>0 )
    y1=mn; 
    else y1=0;

//y2
    if( x2>0 )
    y2=mn+(mx-mn)/4; 
    else y2=0;

//y3
    if( x3>0 )
    y3=mn+(mx-mn)/4; 
    else y3=0;

//y4
    if( x4>0 )
    y4=mn+(mx-mn)/2; 
    else y4=0;

//y5
    if( x5>0 )
    y5=mn+(mx-mn)/2; 
    else y5=0;

//y6
    if( (finalH>0) && ((y1+y2+y3+y4+y5)==0) )
    y6=mn; 
    else y6=0;

    finalL = y1+y2+y3+y4+y5+y6;

    for( i=0; i<OctLinesCnt; i++) {
         mml[i] = 0;
         }
         
   dmml = (finalH-finalL)/8;

   mml[0] =(finalL-dmml*2); //-2/8
   for( i=1; i<OctLinesCnt; i++) {
        mml[i] = mml[i-1] + dmml;
        }
   for( i=0; i<OctLinesCnt; i++ ){
        buff_str = "mml"+i;
        if(ObjectFind(buff_str) == -1) {
           ObjectCreate(buff_str, OBJ_HLINE, 0, Time[0], mml[i]);
           ObjectSet(buff_str, OBJPROP_STYLE, STYLE_SOLID);
           ObjectSet(buff_str, OBJPROP_COLOR, mml_clr[i]);
           ObjectSet(buff_str, OBJPROP_WIDTH, mml_wdth[i]);
           ObjectMove(buff_str, 0, Time[0],  mml[i]);
           }
        else {
           ObjectMove(buff_str, 0, Time[0],  mml[i]);
           }
             
        buff_str = "mml_txt"+i;
        if(ObjectFind(buff_str) == -1) {
           ObjectCreate(buff_str, OBJ_TEXT, 0, Time[mml_shft], mml_shft);
           ObjectSetText(buff_str, ln_txt[i], 8, "Arial", mml_clr[i]);
           ObjectMove(buff_str, 0, Time[mml_shft],  mml[i]);
           }
        else {
           ObjectMove(buff_str, 0, Time[mml_shft],  mml[i]);
           }
        } // for( i=1; i<=OctLinesCnt; i++ ){

   nTime    = Time[0];
   CurPeriod= Period();
   
   string buff_str = "LR_LatestCulcBar";
   if(ObjectFind(buff_str) == -1) {
      ObjectCreate(buff_str, OBJ_ARROW,0, Time[StepBack], Low[StepBack]-2*Point );
      ObjectSet(buff_str, OBJPROP_ARROWCODE, MarkNumber);
      ObjectSet(buff_str, OBJPROP_COLOR, MarkColor);
      }
   else {
      ObjectMove(buff_str, 0, Time[StepBack], Low[StepBack]-2*Point );
      }

   }
 
//---- End Of Program
  return(0);
  }
//+------------------------------------------------------------------+

对水平的解释是至关重要的--这就是为什么该指标的文章部分被作为评论放在里面。但改变MMPeriod变量（默认为1440-天），我们可以在任何时间框架上显示任何其他时期的水平（当然，为了正常工作，显示水平的时期不应小于当前的时期）。也许我提出的想法有点杂乱无章。好运和良好的趋势。

Forex Trader 2006.03.12 14:42 #67

<br / translate="no">实际上，没有什么秘密，而且更多的是：我用来做预测的指标在蜘蛛网上是免费提供的:)。我也会把它放在这里--这是一个Murray水平指标。

谢谢你，Vladislav!我觉得，我们终于有了一个与本论坛主题直接相关的实质性对话了很高兴能与一个了解他正在处理的问题和如何处理的人交谈（外汇）。我也坚信，外汇应该只在统计数据的基础上进行交流，这些数据可以代表数字特征。因为所有给出定性估计的方法，其中包括人字形和埃利奥特方法，都是一种运气游戏，必须在几乎连续呆在显示器附近时进行。基本上，那些已经学会演奏的人，都非常优秀。但大多数人无法学会弹奏它。而且，这甚至不在研究游戏的时间量上。
我想对发布的指标进行澄清。
编译时，它说变量mm_period和StpBck没有被定义。你能指定这些变量的值吗？

Forex Trader 2006.03.12 14:57 #68

<br / translate="no">编译时，它说变量mm_period、StpBck没有被定义。我们可以指定这些变量的值吗？

该代码已被纠正 - 请重新下载。这个片段是从另一个程序中插入的:)。现在一切都可以编译了。
还有一件事我忘了--当设置MMRead = 0时，你会看到相应的倍频程（其尺寸由P变量指定，64的估计值是最好的选择）由当前tf的数据构建。
最重要的是：这种方法不仅适用于外汇工具，这给统计学上的有效性和不太快的崩溃带来了希望（最可能的是，该方法可以 "消除 "市场运动的潜在低效率，崩溃是不可预期的，尽管该方法肯定不是唯一的；）。)，但对我这个或多或少受过适当数学教育的人来说，它似乎是可靠的。

好运和良好的趋势。

Forex Trader 2006.03.12 17:11 #69

弗拉迪斯拉夫，非常感谢你如此详细的解释。

好运!

Forex Trader 2006.03.12 17:45 #70

<br/ translate="no"> 例如，R/S统计（也称为Hurst准则）给欧元价格系列的估计值高于0.5（大约0.64 - 如果你采取整个系列），这又意味着非随机预测的可能性和趋势预测模型的优势。例如，我采取了不同的方法--有些时候，可靠的预测是可能的（Hurst系数与0.5有明显的不同），有些时候是不可能的（没有什么不同）。有一些时刻，当趋势方法是有利的（系数约为1），当反趋势方法是有利的（系数约为0）。

我对你策略中 "可靠预测 "趋势和反趋势操作方法的部分非常感兴趣。你能告诉我们更多关于它的情况吗？换句话说，你如何预测市场处于持平状态并将在一段时间内保持这种状态？我不能做预言。在我的策略中，我只是将市场阶段有条件地分为两个。第一阶段--市场的任何活动（强势趋势、新闻等）和第二阶段--平静阶段（横向通道）。我使用一个微不足道的方法--
标准偏差指标，它是MT4交付的一部分。我简单地定义这样那样的偏差期和指标值将向我显示这两个阶段，在此基础上，我要么下限价单（如果我们目前处于平盘），要么简单地删除它们（如果有一些运动，即指标值已经超过了阈值）。但应该注意的是，这个指标只显示了市场的现状!例如，它不能向你展示或预测未来一小时内将发生什么！它不能向你展示。而你，发表关于 "可靠预测 "的可能性的声明，你怎么能证明呢？请详细说明你们使用的预测方法。

基于艾略特波浪理论的交易策略 - 页 7