Lütfen yayılma konusunda bana yol gösterin

tatyawinchu 2014.04.05 12:02 #11

GumRai :

Bunu 20 veya 30 $ için kodlayabileceğinizi düşünürdüm.

Doğru.. teşekkürler .. Önce ücretsiz bir şey bulabilecek miyim bir bakayım, bir şey bulamazsam iş ilanı veririm.

tatyawinchu 2014.04.05 12:26 #12

GumRai :

Bunu 20 veya 30 $ için kodlayabileceğinizi düşünürdüm.

Aslında, şimdi sipariş kapanışının zaten yayılmayı dikkate aldığını ONAYLADIĞINIZ için, yukarıdaki komut dosyasının benim için çalışması gerektiğini düşünüyorum .. teşekkürler .. Tek yapmam gereken 10 pip .. ve dediğiniz gibi otomatik olarak kapanacak kısa ise ASK değerini, uzun ise BID değerini kullanarak .. ve bunun toplamı toplam hesap karı olarak ve tüm açık emirleri kapatır .. bekleyen emirlere dokunmaz, bu yüzden her şey yolunda .. çok teşekkürler.. ayrıca , lütfen bana açıklar mısınız ..yukarıdaki programda slippage = 5 yazıyor .. bu script için ne anlama geliyor? komut dosyası bir siparişi kapattığında bu nasıl oynayacak? oh ve ayrıca, bu bir komut dosyası mı yoksa EA mı? veya ikisi arasında nasıl ayrım yapılır? [ BU KADAR ÇOK ŞEYİ NASIL ÖĞRENİYORSUNUZ >.< ]

Hisse Senedi EA Herkes? Yeni Fikir sistemi Burada Backtest'te harika EA!

Daniel Petrovai 2014.04.05 19:46 #13

tatyawinchu :

Cok tesekkurler.. Çok net ve çok faydalı.. Acaba böyle bir iş ilanı ne kadara mal olur? Böyle bir kodu değerlendirmek ne kadar zor olabilir? Web'den aldığım ve yukarıda yayınladığım kod BÜYÜK görünüyor .. Yani gerçekten binlerce dolar harcayamam ...

Tekrar merhaba,

Endişelenmenize gerek yok, İstediğiniz şeyin kodu bu kadar karmaşık olmamalı ve sadece bir iş göndermeniz gerekirse, kontrol altında olan sizsiniz, ne kadar ödeyebileceğinizi teklif ediyor ve düşünüyorsunuz. buna değer !

Öte yandan, benim gibiyseniz, önce ücretsiz seçeneği denerdim. Kaybedecek bir şey yok, belki birkaç arkadaş kazanın ve bu süreçte bir şeyler öğrenin.

Şerefe

Uzman Danışmanınızı optimize edin Uzman Danışmanınızı Ücretsiz Oluşturacak! Geliştirme yolumuz. Danışmanlar bugün

Daniel Petrovai 2014.04.05 21:01 #14

tatyawinchu :

Aslında, şimdi sipariş kapanışının zaten yayılmayı dikkate aldığını ONAYLADIĞINIZ için, yukarıdaki komut dosyasının benim için çalışması gerektiğini düşünüyorum .. teşekkürler .. Tek yapmam gereken 10 pip .. ve dediğiniz gibi otomatik olarak kapanacak kısa ise ASK değerini, uzun ise BID değerini kullanarak .. ve bunun toplamı toplam hesap karı olarak ve tüm açık emirleri kapatır .. bekleyen emirlere dokunmaz, bu yüzden her şey yolunda .. çok teşekkürler.. ayrıca , lütfen bana açıklar mısınız ..yukarıdaki programda slippage = 5 yazıyor .. bu script için ne anlama geliyor? komut dosyası bir siparişi kapattığında bu nasıl oynayacak? oh ve ayrıca, bu bir komut dosyası mı yoksa EA mı? veya ikisi arasında nasıl ayrım yapılır? [ BU KADAR ÇOK ŞEYİ NASIL ÖĞRENİYORSUNUZ >.< ]

Tekrar merhaba,

Her zaman olduğu gibi, bir iyi bir de kötü haber var. Önce kötü haberi mi yoksa iyi haberi mi istersin?

İşte burada ve yeterince iyi açıklayamazsam lütfen bana bildirin: Bir EA'nın Hesap karına dayalı işlemlerden çıkabilmesi için, bir başlangıç noktası olması için işlem yapılmadan önce hesap özkaynaklarının ne olduğunu bilmesi gerekir. Bir anlam ifade ediyor mu ?

Karşılaştırmak için bir başlangıç noktanız yoksa veya karşılaştırma yoksa, EA hesap kârınız negatif olduğu sürece işleminizi asla kapatmayacak veya hesap kârınız pozitif ve 100'ün üzerindeyse veya her ne olursa olsun tüm işlemleri hemen kapatacaktır. sınırdır.

Bu bir anlam ifade ediyor mu?

Kayma, piyasa fiyatından açarsanız veya kapatırsanız, komisyoncunun yeniden kotasyon yapmadan emri vermesine veya kapatmasına izin verdiğiniz fiyattan maksimum sapma miktarıdır. fiyat değeri (teklif veya satış) kayma limitleri içindeyse, sipariş işleme alınacak, aksi takdirde yeniden fiyatlandırılacaktır.

Evet, kodunuz bir EA. Bir komut dosyası genellikle yalnızca bir kez çalışır, yeni bir onay işareti alırsınız, kodu yürütür ve çıkarsınız. Bir EA, siz izin verdiğiniz sürece sürekli çalışır.

Onları nasıl ayırt edersiniz? Bazen benzer şekilde çalıştıkları için zordur. Yeni bir komut dosyası oluşturulduğunda şöyle görünür:

 //+------------------------------------------------------------------+
//|                                                   TestScript.mq4 |
//|                             Copyright 2014, 3D@tm Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, 3D@tm Software Corp."
#property link        "https://www.mql5.com"
#property version    "1.00"
#property strict
//+------------------------------------------------------------------+
//| Script program start function                                    |
//+------------------------------------------------------------------+
void OnStart ()
  {
//---
   
  }
//+------------------------------------------------------------------+

Yalnızca OnStart işlevine sahip olduğunu ve şunu yazdığını görebilirsiniz: Komut dosyası programı başlatma işlevi.

Sorununuza geri dönersek, herhangi bir emir verilmediğinde hesabı kontrol eden ve bunu bir referans noktası olarak alan bir EA çalıştırırsanız, hesap başına istenen kâra ulaşıldığında tüm siparişleri kapatabilir.

Bir pipin değeri (pip başına para) tüm para birimleri için aynı değildir. AUDUSD çiftindeki bir pip, GBPJPY çiftindeki ile aynı değerde değildir.

Bu EA için belirli semboller mi arıyorsunuz yoksa sadece hesap başına kâra ulaşıldığında tüm siparişleri kapatmak için hangi sembol olursa olsun?

Ayrıca, zararı durdurma hesabı öz sermaye ile mi yoksa emir/çift ile mi ilgili olmalıdır?

Kulağa karmaşık geldiğini biliyorum ama o kadar da karmaşık değil. Bilgisayarlarımız o kadar aptal ki, tam olarak ne istediğinizi belirtmezseniz kaybolurlar.

Bunun size bir yardımı oldu mu? Umarım öyleydi.

Şerefe

Uzak sunucularda EA? Mql4 dilinin özellikleri, incelikleri Hisse Senedi EA Herkes?

Keith Watford 2014.04.05 21:45 #15

üçüncü

AccountProfit()'in mevcut açık işlemler için toplam karı döndürdüğünden oldukça eminim. Yine de belgelerden açık değil.

Syed Naufal Gaddafi 2014.04.05 22:08 #16

GumRai :

üçüncü

AccountProfit()'in mevcut açık işlemler için toplam karı döndürdüğünden oldukça eminim. Yine de belgelerden açık değil.

Hmm ...

 AccountProfit ()

Bunun yerine kullanıyorum...

 double AccProfits=AccProfits+ OrderProfit ();

Neye ulaşmak istediğine bağlı.

Daniel Petrovai 2014.04.05 22:47 #17

GumRai :

üçüncü

AccountProfit()'in mevcut açık işlemler için toplam karı döndürdüğünden oldukça eminim. Yine de belgelerden açık değil.

Merhaba GumRai ,

Haklısın, belgelerden çok açık değil ama test ettim ve tekrar haklısın, açık olan tüm siparişlerdeki kar/zararın toplamıdır.

İyi yakaladın. Teşekkürler.

Yalnızca manuel olarak açılan siparişleri yönetmek istiyorsanız ve diğer EA'lar tarafından verilebilecek diğer siparişler arasından seçim yapmanız gerekiyorsa, yine de Hesap Karını kullanamazsınız.

Sanırım sihirli sayı = 0 ile seçim yapmak hile yapmalı. Sonra deysmacro'nun önerdiği gibi kârları toplayın.

Sanırım ben böyle görüyorum. Siz ne düşünüyorsunuz?

 //+------------------------------------------------------------------+
//|                                       CloseOrdersOnProfit_v1.mq4 |
//|                             Copyright 2014, 3D@tm Software Corp. |
//|                                              https://www.mql5.com |
//+------------------------------------------------------------------+
#property copyright "Copyright 2014, 3D@tm Software Corp."
#property link        "https://www.mql5.com"
#property version    "1.00"
#property strict
//---
#include <stdlib.mqh>
//---
#define RETRYCOUNT     10
#define RETRYDELAY     500
#define LONG           1
#define SHORT         - 1
#define ALL           0
//---
extern int      Slippage= 3 ;
input    double   ProfitTarget= 100.0 ;
input    double   StopLossLimit= 50.0 ;
input    bool     WriteScreenshots= true ;
//---
double StartEquity= 0 ;
int     myOrders;
//===================================================================
/*
This EA will manage manually placed orders and skip the orders that
have a magic number different from zero.
If the Profit target - the sum of profit/loss on all orders (except
orders placed by other EA's ) is reached, all those orders are
closed.
If the maximum amount of money allowed for a loss is reached, EA
will close all those orders and an alert will pop up.
*/
//===================================================================
//+------------------------------------------------------------------+
//| Expert initialization function                                   |
//+------------------------------------------------------------------+
int OnInit ()
  {
//---
   if ( Digits == 3 || Digits == 5 ) Slippage*= 10 ;
//---
   return ( INIT_SUCCEEDED );
  }
//+------------------------------------------------------------------+
//| Expert deinitialization function                                 |
//+------------------------------------------------------------------+
void OnDeinit ( const int reason)
  {
//---

  }
//+------------------------------------------------------------------+
//| Expert tick function                                             |
//+------------------------------------------------------------------+
void OnTick ()
  {
//--- count orders manually placed (no magic number)
   CountMyOrders();
//--- reset account equity / take a reference point
   if (myOrders< 1 )
     {
      StartEquity= AccountEquity ();
       //--- no orders detected, wait for orders to be placed
       return ;
     }
//--- calculate profit
   double myProfit=CalculateProfit();
//--- if profit target reached, exit all
   if (myProfit>=ProfitTarget)
     {
      ExitAll(ALL);
       Alert ( "Orders closed due to profit target reached" );
     }
//--- exit if stop limit reached
   if (StartEquity- AccountEquity ()>=StopLossLimit)
     {
      ExitAll(ALL);
       Alert ( "Orders closed due to stop loss limit reached" );
     }

   return ;
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double CountMyOrders()
  {
   myOrders= 0 ;
   for ( int cnt= OrdersTotal ()- 1 ;cnt>= 0 ;cnt--)
     {
       if ( OrderSelect (cnt, SELECT_BY_POS , MODE_TRADES )== false )
         Print ( "Failed to select order, error : " +ErrorDescription(GetLastError()));
       //skip orders placed by other EA's
       if ( OrderMagicNumber ()> 0 ) continue ;
       if ( OrderType ()== OP_BUY || OrderType ()== OP_SELL )
        {
         myOrders++;
        }
     }
   return (myOrders);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
double CalculateProfit()
  {
   double Profit= 0 ;
   for ( int cnt= OrdersTotal ()- 1 ;cnt>= 0 ;cnt--)
     {
       if ( OrderSelect (cnt, SELECT_BY_POS , MODE_TRADES )== false )
         Print ( "Failed to select order, error : " +ErrorDescription(GetLastError()));
       //skip orders placed by other EA's
       if ( OrderMagicNumber ()> 0 ) continue ;
       if ( OrderType ()== OP_BUY || OrderType ()== OP_SELL )
        {
         Profit=Profit+ OrderProfit ();
        }
     }
   return (Profit);
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void ExitAll( int direction)
  {

   string total= IntegerToString ( OrdersTotal (), 0 , 0 );

   for ( int i= OrdersTotal ()- 1 ; i>= 0 ; i--)
     {
       Comment ( StringConcatenate ( "Closing trade #" ,(i+ 1 )));
       if ( OrderSelect (i, SELECT_BY_POS , MODE_TRADES )== false )
         Print ( "Failed to select order, error : " +ErrorDescription(GetLastError()));
       //skip orders placed by other EA's
       if ( OrderMagicNumber ()> 0 ) continue ;
       //---
       if ( OrderType ()== OP_BUY &&(direction==LONG ||  direction==ALL)) { Exit( OrderSymbol (), OrderTicket (),LONG, OrderLots (),Blue); }
       if ( OrderType ()== OP_SELL &&(direction==SHORT|| direction==ALL)) { Exit( OrderSymbol (), OrderTicket (),SHORT, OrderLots (),Red); }
     }
   Comment ( StringConcatenate (total, " trades closed." ));
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
bool Exit( string symb , int ticket, int dir, double volume, color clr, int t= 0 )
  {
   int i= 0 ,j= 0 ,cmd= 0 ;
   double prc= 0 ,sl= 0 ,tp= 0 ,lots= 0 ;
   string cmt;
   double bid= MarketInfo (symb, MODE_BID );
   double ask= MarketInfo (symb, MODE_ASK );
   bool closed;

   Print ( "Exit(" + IntegerToString (dir, 0 , 0 )+ "," + DoubleToStr (volume, 3 )+ "," + IntegerToString (t, 0 , 0 )+ ")" );

   for (i= 0 ; i<RETRYCOUNT; i++) 
     {
       for (j= 0 ;(j< 50 ) && IsTradeContextBusy (); j++)
         Sleep ( 100 );
       RefreshRates ();

       if (dir==LONG) 
        {
         prc=bid;
        }
       if (dir==SHORT) 
        {
         prc=ask;
        }
       Print ( "Exit: prc=" + DoubleToStr (prc, Digits ));

      closed= OrderClose (ticket,volume,prc,Slippage,clr);
       if (closed)
        {
         Print ( "Trade closed" );
         Screenshot( "Exit" );

         return ( true );
        }

       Print ( "Exit: error \'" +ErrorDescription(GetLastError())+ "\' when exiting with " + DoubleToStr (volume, 3 )+ " @" + DoubleToStr (prc, Digits ));
       Sleep (RETRYDELAY);
     }

   Print ( "Exit: can\'t enter after " + IntegerToString (RETRYCOUNT, 0 , 0 )+ " retries" );
   return ( false );
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
void Screenshot( string moment_name)
  {
   if (WriteScreenshots)
       WindowScreenShot ( WindowExpertName ()+ "_" + Symbol ()+ "_M" + IntegerToString ( Period (), 0 , 0 )+ "_" +
                       IntegerToString ( Year (), 0 , 0 )+ "-" +two_digits( Month ())+ "-" +two_digits( Day ())+ "_" +
                       two_digits( Hour ())+ "-" +two_digits( Minute ())+ "-" +two_digits( Seconds ())+ "_" +
                       moment_name+ ".gif" , 1024 , 768 );
  }
//+------------------------------------------------------------------+
//|                                                                  |
//+------------------------------------------------------------------+
string two_digits( int i)
  {
   if (i< 10 )
       return ( "0" + IntegerToString (i, 0 , 0 ));
   else
       return ( "" + IntegerToString (i, 0 , 0 ));
  }
//+------------------------------------------------------------------+

Tartışma Sonlandırıcı v2.0 Yeni başlayanlardan sorular MQL4

Tjipke de Vries 2014.04.06 03:35 #18

thrdel :

Merhaba GumRai ,

Haklısın, belgelerden çok açık değil ama test ettim ve tekrar haklısın, açık olan tüm siparişlerdeki kar/zararın toplamıdır.

İyi yakaladın. Teşekkürler.

Yalnızca manuel olarak açılan siparişleri yönetmek istiyorsanız ve diğer EA'lar tarafından verilebilecek diğer siparişler arasından seçim yapmanız gerekiyorsa, yine de Hesap Karını kullanamazsınız.

Sanırım sihirli sayı = 0 ile seçim yapmak hile yapmalı. Sonra deysmacro'nun önerdiği gibi kârları toplayın.

Sanırım ben böyle görüyorum. Siz ne düşünüyorsunuz?

bu başarısız .....

birçok işlem için prc doğru fiyat değil

ayrıca yapma

   if ( Digits == 3 || Digits == 5 ) Slippage*= 10 ;

zaman diliminizi birkaç kez değiştirirseniz ......

Daniel Petrovai 2014.04.06 06:05 #19

deVries :

bu başarısız .....

birçok işlem için prc doğru fiyat değil

ayrıca yapma

zaman diliminizi birkaç kez değiştirirseniz ......

Evet deVries ,

her şey başarısız oluyor ve sen öyle diyorsan bunu yapmamalıyım, ama gerçekten cevap vermende pek bir yardım göremediğim için .....

Kodun telaşlı bir müşteriye satılmak üzere tasarlanmış ticari bir EA olmadığını anlıyorsunuz, değil mi Bir şeyleri çözmeye çalışıyoruz ve yardım etmek istemiyorsanız, en azından kendi haline bırakmalısınız.

Zaman çerçevesini birkaç kez değiştirirsem gerçekten bunu mu düşünüyorsunuz..... ne? Kayma 3000000 olacak mı? Görünüşe göre MT4'ümde değil. Ve bana inanmıyorsanız, kendiniz bir test yapın.

Testim, zaman dilimlerini değiştirdiğinizde, EA'nın deinit/init döngüsünden geçtiğini ve bahsedilen kod OnInit'te olduğundan, Slippage'in her seferinde 30 noktada olacağını söylüyor.

Herkesin görebileceği gibi, önerdiğiniz buysa, zaman dilimlerini değiştirmek Kayma'yı bir milyona getirmeyecektir.

Ve hayır, bu sahte bir resim değil, gerçek, her zaman dilimini değiştirme zamanını kontrol edebilirsiniz.

Umarım yardımcı olur.

yeni başlayan birinin maceraları müthiş performans Servis masası. Şikayetler, öneriler.

tatyawinchu 2014.04.06 06:27 #20