Caratteristiche utili da KimIV

Igor Kim 2008.04.16 13:43 #121

olyakish:

Igor, ti ho fatto una domanda nella 'Libreria di funzioni per lavorare con i file INI', ma non c'è stata risposta :(

Grazie... ha risposto...

Igor Kim 2008.04.16 14:08 #122

La funzione ClosePosBySelect().

Chiude una posizione preselezionata. Questa funzione è piuttosto ausiliaria, perché è chiamata da diverse altre funzioni, che aiutano a selezionare le posizioni da chiudere in base ad alcune condizioni.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 19.02.2008                                                      |
//|  Описание: Закрытие одной предварительно выбранной позиции                 |
//+----------------------------------------------------------------------------+
void ClosePosBySelect() {
  bool   fc;
  color  clClose;
  double ll, pa, pb, pp;
  int    err, it;

  if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      pa=MarketInfo(OrderSymbol(), MODE_ASK);
      pb=MarketInfo(OrderSymbol(), MODE_BID);
      if (OrderType()==OP_BUY) {
        pp=pb; clClose=clCloseBuy;
      } else {
        pp=pa; clClose=clCloseSell;
      }
      ll=OrderLots();
      fc=OrderClose(OrderTicket(), ll, pp, Slippage, clClose);
      if (fc) {
        if (UseSound) PlaySound(NameFileSound); break;
      } else {
        err=GetLastError();
        if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
        Print("Error(",err,") Close ",GetNameOP(OrderType())," ",
              ErrorDescription(err),", try ",it);
        Print(OrderTicket(),"  Ask=",pa,"  Bid=",pb,"  pp=",pp);
        Print("sy=",OrderSymbol(),"  ll=",ll,"  sl=",OrderStopLoss(),
              "  tp=",OrderTakeProfit(),"  mn=",OrderMagicNumber());
        Sleep(1000*5);
      }
    }
  } else Print("Некорректная торговая операция. Close ",GetNameOP(OrderType()));
}

Alexey Klenov 2008.04.17 11:28 #123

KimIV:

Grazie... ha risposto...

Un'altra domanda (o piuttosto affermazione) anche lì :)

alexvor 2008.04.17 13:21 #124

KimIV:

La funzione ClosePosBySelect().

Chiude una posizione preselezionata. Questa funzione è piuttosto ausiliaria perché è chiamata da diverse altre funzioni che aiutano a selezionare le posizioni da chiudere secondo alcune condizioni.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 19.02.2008                                                      |
//|  Описание: Закрытие одной предварительно выбранной позиции                 |
//+----------------------------------------------------------------------------+
void ClosePosBySelect() {
  bool   fc;
  color  clClose;
  double ll, pa, pb, pp;
  int    err, it;

  if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
    for (it=1; it<=NumberOfTry; it++) {
      if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) break;
      while (!IsTradeAllowed()) Sleep(5000);
      RefreshRates();
      pa=MarketInfo(OrderSymbol(), MODE_ASK);
      pb=MarketInfo(OrderSymbol(), MODE_BID);
      if (OrderType()==OP_BUY) {
        pp=pb; clClose=clCloseBuy;
      } else {
        pp=pa; clClose=clCloseSell;
      }
      ll=OrderLots();
      fc=OrderClose(OrderTicket(), ll, pp, Slippage, clClose);
      if (fc) {
        if (UseSound) PlaySound(NameFileSound); break;
      } else {
        err=GetLastError();
        if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
        Print("Error(",err,") Close ",GetNameOP(OrderType())," ",
              ErrorDescription(err),", try ",it);
        Print(OrderTicket(),"  Ask=",pa,"  Bid=",pb,"  pp=",pp);
        Print("sy=",OrderSymbol(),"  ll=",ll,"  sl=",OrderStopLoss(),
              "  tp=",OrderTakeProfit(),"  mn=",OrderMagicNumber());
        Sleep(1000*5);
      }
    }
  } else Print("Некорректная торговая операция. Close ",GetNameOP(OrderType()));
}

Ciao!

Mi scusi!

1) Non capisco il significato della linea for (it=1; it<=NumberOfTry; it++)

che tipo di loop è questo?

2) Non capisco anche la condizione if (!testing() ......) break;

3) e infine, che funzione è questa? ErrorDescription(err)," ,

Se non le dispiace, mi spieghi.

C'è bisogno di un Teorema sulla presenza di Ancora una volta, a

Igor Kim 2008.04.18 01:23 #125

1. questo è un ciclo di tentativi di commercio. Se il server commerciale restituisce errori, la funzione farà un numero di tent ativi per chiudere la posizione dopo tutto. Di solito imposto NumberOfTry=5.

2. questa condizione implementa la capacità di uscire correttamente dal ciclo di tentativi quando l 'Expert Advisor che lavora online viene fermato. Senza questa condizione, per chiamare, per esempio, le proprietà dell'EA, dovevamo aspettare che l'EA utilizzasse tutti i tentativi di trade, o rimuovere l'EA dal grafico.

3. Guarda nel file ..■experts\libraries\stdlib.mq4

Qualsiasi domanda da principiante, Un programma per monitorare La tela è forte!

[Eliminato] 2008.04.18 07:24 #126

Vorrei chiedere come far lavorare un EA in un ciclo infinito, ma con accesso alle impostazioni dei suoi parametri?

Ho scritto all'inizio così

while (true)
{
  // проверка на останов и прочее
      if (IsStopped()) 
        return(-1);
  while (isRefresh == false)
       isRefresh = RefreshRates();
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

Ma in questo caso, l'Expert Advisor si blocca e non posso fare nulla con esso tranne che rimuoverlo dal grafico

Dalla teoria alla pratica EURUSD - Tendenze, previsioni [Qualsiasi domanda da principiante,

Igor Kim 2008.04.18 13:07 #127

Valera, fa che sia così:

while (IsExpertEnabled() && !IsStopped())
{
  while (!RefreshRates()) Sleep(500);
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

Igor Kim 2008.04.20 06:18 #128

La funzione ClosePosBySizeProfitInCurrency().

Questa funzione chiude solo le posizioni per le quali il profitto nella valuta di deposito supera un certo valore specificato. Potete specificare quali posizioni devono essere chiuse usando i parametri della funzione:

sy - Nome dello strumento. Se impostate questo parametro, la funzione controllerà solo le posizioni dello strumento specificato. NULL significa lo strumento corrente, e "" (di default) significa qualsiasi strumento.
op - operazione commerciale, tipo di posizione. Valori validi: OP_BUY, OP_SELL o -1. Il valore predefinito -1 significa qualsiasi posizione.
mn - Identificatore di posizione (MagicNumber). Valore predefinito -1 - significa qualsiasi MagicNumber.
pr - Livello di profitto nella valuta di deposito. Valore predefinito - 0.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 19.02.2008                                                     |
//|  Описание : Закрытие тех позиций, у которых профит в валюте депозита       |
//|             превысил некоторое значение                                    |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (""   - любой символ,                   |
//|                                     NULL - текущий символ)                 |
//|    op - операция                   (-1   - любая позиция)                  |
//|    mn - MagicNumber                (-1   - любой магик)                    |
//|    pr - профит                                                             |
//+----------------------------------------------------------------------------+
void ClosePosBySizeProfitInCurrency(string sy="", int op=-1, int mn=-1, double pr=0) {
  int i, k=OrdersTotal();

  if (sy=="0") sy=Symbol();
  for (i=k-1; i>=0; i--) {
    if (OrderSelect(i, SELECT_BY_POS, MODE_TRADES)) {
      if ((OrderSymbol()==sy || sy=="") && (op<0 || OrderType()==op)) {
        if (OrderType()==OP_BUY || OrderType()==OP_SELL) {
          if (mn<0 || OrderMagicNumber()==mn) {
            if (OrderProfit()+OrderSwap()>pr) ClosePosBySelect();
          }
        }
      }
    }
  }
}

Solo "Caratteristiche utili di E facciamone un "cartone Tutte le domande dei

[Eliminato] 2008.04.22 05:54 #129

KimIV:

Valera, fa che sia così:

while (IsExpertEnabled() && !IsStopped())
{
  while (!RefreshRates()) Sleep(500);
      
  // некий код
  // задержка
  Sleep(G_Period);   
}

Ahimè, questo trasmette anche l'ekspert e non dà accesso ai suoi parametri finché non lo si rimuove dal grafico

Igor Kim 2008.04.22 06:55 #130

scorpionk:

Ahimè, questo trasmette anche l'EA e non dà accesso ai suoi parametri fino a quando non lo si rimuove dal grafico

Tuttavia, ti dà la possibilità di fermare l'EA premendo il pulsante 'EAs' sulla barra degli strumenti.

Caratteristiche utili da KimIV - pagina 13

La funzione ClosePosBySelect().

La funzione ClosePosBySelect().

La funzione ClosePosBySizeProfitInCurrency().