Caratteristiche utili da KimIV

kombat 2008.03.20 19:05 #41

Grazie per aver accettato... ;)

Cos'è AND, OR, NOT
non è difficile da capire, sono solo interessato a queste piccole cose nel codice e ai loro usi.

O, per esempio, questo:
- la condizione a è EQUALE a b è facile da implementare a==b
- Ma la condizione a è UNEQUALE a b è difficile da implementare...

Scusate se riprendo le basi, ma questo probabilmente tornerà utile a molti principianti...

Ecco un codice già pronto con condizioni di addestramento al combattimento. :)
Ha tutto... dalla definizione e sistemazione dei campi alla scrittura del programmatore...
https://www.mql5.com/ru/forum/51521

Tutte le domande dei Media mobile Domande dai principianti MQL4

Igor Kim 2008.03.20 19:24 #42

kombat писал (а):
- Ma la condizione a è INEGUALE a b sta già causando difficoltà...

a!=b;

igor 2008.03.20 19:39 #43

Mi sembra, Igor, che tu abbia deviato un po' dall'argomento e ti sia addentrato in spiegazioni.
Se posso, vorrei suggerire una funzione che mostra qualsiasi cosa nel collegamento della barra delle applicazioni.
Lo uso per monitorare le prestazioni degli EA al lavoro senza aprire il terminale (molti occhi indiscreti).
può essere utile anche in altri casi.

//----------- Funzione di visualizzazione nella barra delle applicazioni -------------------------------------
void ProfMT(string X)
{
int hwnd1 = WindowHandle(Symbol(), Period());
int hwnd_parent1 = 0;
while (!IsStopped())
{
hwnd1= GetParent(hwnd1);
if (hwnd1 == 0) break;
hwnd_parent1 = hwnd1;
}
if (hwnd_parent1 != 0) SetWindowTextA(hwnd_parent1,X);
}
Grazie.

Grafico dell'equità e dell'equilibrio Auguri per MQL5 Indicatori multi timeframe

kombat 2008.03.20 19:44 #44

Ecco fatto... Dove altro si può imparare la verità così rapidamente che in un forum... ;)

Grazie e scusate se sono andato fuori tema.
Cercherò di fare altre domande nel thread del libro...

Signor commerciante, di quanti [Qualsiasi domanda da principiante, Dalla teoria alla pratica

Igor Kim 2008.03.21 05:11 #45

La funzione OpenPosition() per il tester.

Progettato per aprire posizioni - operazioni di trading di acquisto o vendita a prezzi di mercato. Questa funzione è universale e multivaluta, permettendo di aprire posizioni per qualsiasi simbolo, non solo per quello corrente. Per esempio, un EA può essere eseguito sul grafico EURUSD e commerciare USDCAD.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия  : 13.06.2007                                                      |
//|  Описание : Открытие позиции. Версия функции для тестов на истории.        |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   ("" - текущий символ)                   |
//|    op - операция                                                           |
//|    ll - лот                                                                |
//|    sl - уровень стоп                                                       |
//|    tp - уровень тейк                                                       |
//|    mn - MagicNumber                                                        |
//+----------------------------------------------------------------------------+
void OpenPosition(string sy, int op, double ll, double sl=0, double tp=0, int mn=0) {
  color  clOpen;
  double pp;
  int    err, ticket;
 
  if (sy=="") sy=Symbol();
  if (op==OP_BUY) {
    pp=MarketInfo(sy, MODE_ASK); clOpen=clOpenBuy;
  } else {
    pp=MarketInfo(sy, MODE_BID); clOpen=clOpenSell;
  }
  ticket=OrderSend(sy, op, ll, pp, Slippage, sl, tp, "", mn, 0, clOpen);
  if (ticket<0) {
    err=GetLastError();
    Print("Error(",err,") open ",GetNameOP(op),": ",ErrorDescription(err));
    Print("Ask=",Ask," Bid=",Bid," sy=",sy," ll=",ll,
          " pp=",pp," sl=",sl," tp=",tp," mn=",mn);
  }
}

Pair trading. Come chiudere [Qualsiasi domanda da principiante, Campionato di trading automatizzato

Igor Kim 2008.03.21 05:13 #46

Funzione OpenPosition() per l'online.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 21.03.2008                                                     |
//|  Описание : Открывает позицию и возвращает её тикет.                       |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (NULL или "" - текущий символ)          |
//|    op - операция                                                           |
//|    ll - лот                                                                |
//|    sl - уровень стоп                                                       |
//|    tp - уровень тейк                                                       |
//|    mn - MagicNumber                                                        |
//+----------------------------------------------------------------------------+
int OpenPosition(string sy, int op, double ll, double sl=0, double tp=0, int mn=0) {
  color    clOpen;
  datetime ot;
  double   pp, pa, pb;
  int      dg, err, it, ticket=0;
  string   lsComm=WindowExpertName()+" "+GetNameTF(Period());
 
  if (sy=="" || sy=="0") sy=Symbol();
  if (op==OP_BUY) clOpen=clOpenBuy; else clOpen=clOpenSell;
  for (it=1; it<=NumberOfTry; it++) {
    if (!IsTesting() && (!IsExpertEnabled() || IsStopped())) {
      Print("OpenPosition(): Остановка работы функции");
      break;
    }
    while (!IsTradeAllowed()) Sleep(5000);
    RefreshRates();
    dg=MarketInfo(sy, MODE_DIGITS);
    pa=MarketInfo(sy, MODE_ASK);
    pb=MarketInfo(sy, MODE_BID);
    if (op==OP_BUY) pp=pa; else pp=pb;
    pp=NormalizeDouble(pp, dg);
    ot=TimeCurrent();
    ticket=OrderSend(sy, op, ll, pp, Slippage, sl, tp, lsComm, mn, 0, clOpen);
    if (ticket>0) {
      if (UseSound) PlaySound(NameFileSound); break;
    } else {
      err=GetLastError();
      if (pa==0 && pb==0) Message("Проверьте в Обзоре рынка наличие символа "+sy);
      // Вывод сообщения об ошибке
      Print("Error(",err,") opening position: ",ErrorDescription(err),", try ",it);
      Print("Ask=",pa," Bid=",pb," sy=",sy," ll=",ll," op=",GetNameOP(op),
            " pp=",pp," sl=",sl," tp=",tp," mn=",mn);
      // Блокировка работы советника
      if (err==2 || err==64 || err==65 || err==133) {
        gbDisabled=True; break;
      }
      // Длительная пауза
      if (err==4 || err==131 || err==132) {
        Sleep(1000*300); break;
      }
      if (err==128 || err==142 || err==143) {
        Sleep(1000*66.666);
        if (ExistPositions(sy, op, mn, ot)) {
          if (UseSound) PlaySound(NameFileSound); break;
        }
      }
      if (err==140 || err==148 || err==4110 || err==4111) break;
      if (err==141) Sleep(1000*100);
      if (err==145) Sleep(1000*17);
      if (err==146) while (IsTradeContextBusy()) Sleep(1000*11);
      if (err!=135) Sleep(1000*7.7);
    }
  }
  return(ticket);
}

Igor Kim 2008.03.21 05:25 #47

Esempi di utilizzo della funzione OpenPosition().

1. Compra 0.1 lotto dello strumento corrente

OpenPosition(NULL, OP_BUY, 0.1);

2. Vendere 0,2 lotti di EURUSD

string sy="EURUSD";
double pa=MarketInfo("EURUSD", MODE_ASK);
double pb=MarketInfo("EURUSD", MODE_BID);
double po=MarketInfo("EURUSD", MODE_POINT);
OpenPosition(sy, OP_SELL, 0.2);

3. Vendi 0,12 lotti di USDCAD con uno stop di 20 pip

string sy="USDCAD";
double pa=MarketInfo("USDCAD", MODE_ASK);
double pb=MarketInfo("USDCAD", MODE_BID);
double po=MarketInfo("USDCAD", MODE_POINT);
OpenPosition("USDCAD", OP_SELL, 0.12, pb+20*po);

4. Comprare 0,15 lotti di USDJPY con 40 pip di stop

string sy="USDJPY";
double pa=MarketInfo("USDJPY", MODE_ASK);
double pb=MarketInfo("USDJPY", MODE_BID);
double po=MarketInfo("USDJPY", MODE_POINT);
OpenPosition("USDJPY", OP_BUY, 0.15, 0, pa+40*po);

5. Vendi 0,1 lotto di GBPJPY con stop 23 e takeaway 44 pips

string sy="GBPJPY";
double pa=MarketInfo("GBPJPY", MODE_ASK);
double pb=MarketInfo("GBPJPY", MODE_BID);
double po=MarketInfo("GBPJPY", MODE_POINT);
OpenPosition("GBPJPY", OP_SELL, 0.1, pb+23*po, pb-44*po);

Il trailer è uno script per testare la funzione OpenPosition(). I primi 4 esempi sono commentati.

File:

test_openposition.mq4 11 kb

lukyanov 2008.03.21 10:50 #48

KimIV:

Funzione OpenPosition() per l'online.

//+----------------------------------------------------------------------------+
//|  Автор    : Ким Игорь В. aka KimIV,  http://www.kimiv.ru                   |
//+----------------------------------------------------------------------------+
//|  Версия   : 21.03.2008                                                     |
//|  Описание : Открывает позицию и возвращает её тикет.                       |
//+----------------------------------------------------------------------------+
//|  Параметры:                                                                |
//|    sy - наименование инструмента   (NULL или "" - текущий символ)          |
//|    op - операция                                                           |
//|    ll - лот                                                                |
//|    sl - уровень стоп                                                       |
//|    tp - уровень тейк                                                       |
//|    mn - MagicNumber                                                        |
//+----------------------------------------------------------------------------+
int OpenPosition(string sy, int op, double ll, double sl=0, double tp=0, int mn=0) {
//-- skip --
  string   lsComm=WindowExpertName()+" "+GetNameTF(Period());
//-- skip --

Perché non mettere lsComm nei parametri della funzione? Per esempio, così:

int OpenPosition(string sy, int op, double ll, double sl=0, double tp=0, string lsComm="", int mn=0) {
  color    clOpen;
  datetime ot;
  double   pp, pa, pb;
  int      dg, err, it, ticket=0;
  
  if (lsComm=="" || lsComm=="0") lsComm=WindowExpertName()+" "+GetNameTF(Period());
  if (sy=="" || sy=="0") sy=Symbol();

Imho, la "flessibilità" della funzione si espande...

Igor Kim 2008.03.21 11:19 #49

Lukyanov писал (а):
Perché non mettere lsComm nei parametri della funzione?
Imho, la "flessibilità" della funzione si espande...

Non mi dispiace... Voglio dire che ti permetto di farlo :-)

lukyanov 2008.03.21 13:02 #50

L'ho fatto per me stesso. Potrebbe tornare utile a qualcuno. :-)

Caratteristiche utili da KimIV - pagina 5

La funzione OpenPosition() per il tester.

Funzione OpenPosition() per l'online.

Esempi di utilizzo della funzione OpenPosition().

Funzione OpenPosition() per l'online.